Patron Composite

Le modèle Composite construit des arbres dans lesquels un objet unique et un groupe d’objets ont les mêmes méthodes, afin que le code puisse traiter tout un groupe comme un seul élément. Un sac contient des éléments, un sac peut contenir d’autres sacs, et tu peux demander le poids de chacun de la même manière.

Les deux types partagent un parent abstrait :

# entry.gd
@abstract
class_name Entry
extends RefCounted

var entry_name: String

@abstract func get_weight() -> int
@abstract func display(indent: String) -> void

La feuille est un élément unique :

# item.gd
class_name Item
extends Entry

var weight: int

func _init(n: String, w: int) -> void:
	entry_name = n
	weight = w

func get_weight() -> int:
	return weight

func display(indent: String) -> void:
	print(indent, entry_name, " (", weight, ")")

Le composite contient d’autres entrées et obtient des réponses en interrogeant chacune d’elles. Un sac pèse lui-même 1 :

# bag.gd
class_name Bag
extends Entry

var contents: Array[Entry] = []

func _init(n: String) -> void:
	entry_name = n

func add(entry: Entry) -> void:
	contents.append(entry)

func get_weight() -> int:
	var total := 1
	for entry in contents:
		total += entry.get_weight()
	return total

func display(indent: String) -> void:
	print(indent, entry_name, " [", get_weight(), "]")
	for entry in contents:
		entry.display(indent + "  ")

# main.gd
var pouch := Bag.new("Pouch")
pouch.add(Item.new("Gem", 2))
var backpack := Bag.new("Backpack")
backpack.add(Item.new("Sword", 8))
backpack.add(pouch)
backpack.display("")

Backpack [12]
  Sword (8)
  Pouch [3]
    Gem (2)

Bag.get_weight() ne vérifie jamais si une entrée est un objet ou un sac : elle appelle la même méthode sur chacun d’eux, et un sac imbriqué répond en interrogeant son propre contenu. Cette récursion parcourt tout l’arbre, quelle que soit sa profondeur.

Les liens vont dans un seul sens, d’un sac vers son contenu. Si chaque entrée stockait également le sac dans lequel elle se trouve, chaque sac et ses entrées pointeraient les uns vers les autres, créant un cycle de références qui n’est jamais libéré. Lorsqu’une entrée a besoin de savoir où elle se trouve, transmettez cette information en argument, comme display() transmet l’indentation.