Patron Singleton

Le modèle Singleton garantit qu’une classe possède exactement un objet et offre à chaque script un moyen d’y accéder. Utilise-le pour les éléments dont un jeu ne possède qu’un seul exemplaire : les paramètres, le système de sauvegarde, le gestionnaire de score.

En GDScript, un static var conserve l’unique objet, et une static func le crée la première fois que quelqu’un le demande :

# game_settings.gd
class_name GameSettings
extends RefCounted

static var _instance: GameSettings = null

var volume := 50

static func get_instance() -> GameSettings:
	if _instance == null:
		_instance = GameSettings.new()
		print("Creating settings")
	return _instance

_instance appartient à la classe, et non à un objet, donc tous les scripts voient la même variable. Le premier appel la trouve vide et crée l’objet ; chaque appel suivant renvoie ce même objet.

# main.gd
var a := GameSettings.get_instance()
var b := GameSettings.get_instance()
a.volume = 80
print(b.volume)
print(a == b)

Creating settings
80
true

a et b sont deux variables qui contiennent un même objet ; la modification effectuée via a est donc visible via b. Pour les objets, == vaut true uniquement lorsque les deux côtés désignent le même objet.

GDScript ne peut pas rendre _init() privé, donc rien n’empêche un script d’appeler GameSettings.new() et d’obtenir un deuxième objet. Le trait de soulignement dans _instance et la méthode get_instance() constituent la convention : les scripts demandent l’objet, ils ne le créent jamais.

Dans un projet Godot, la méthode habituelle pour obtenir un objet partagé consiste à utiliser un autoload : un script que tu enregistres dans les paramètres du projet, que Godot crée une seule fois au démarrage du jeu et qu’il rend accessible par son nom dans chaque script. C’est un Singleton que Godot gère pour toi. Les autoloads se configurent dans l’éditeur ; les défis présentés ici mettent donc en place le modèle en code avec static var.