Note moyenne

Fait partie de la section Logique et flux d’exécution du Journey GDScript de Coddy. Leçon 46 sur 78.

Défi

Facile

Calcule la moyenne des notes d’un élève. Garde tout ce que tu as écrit dans les étapes précédentes.

1. La fonction. Sous les autres fonctions, écris calculate_average_grade(student_name: String) -> float :

Si student_records ne contient pas le nom, affiche Student '<name>' not found. et renvoie -1.0. Aucune moyenne réelle n’est négative, donc l’appelant peut savoir que l’élève était absent.
Si l’élève n’a pas encore de notes, renvoie 0.0.
Sinon, renvoie la somme des notes divisée par leur nombre, sous forme de float.

2. La commande. Ajoute cette branche pour average <name> au-dessus de ["show"]. Elle affiche la moyenne avec deux décimales, sauf si l’élève est introuvable :

["average", var student]:
	var average := calculate_average_grade(student)
	if average >= 0:
		print("Average grade of '%s': %.2f" % [student, average])

Pour les commandes

add Alice 20 Math Physics
add Bob 22 Biology Chemistry
grade Alice 90
grade Alice 85
grade Bob 75
average Alice
average Bob
average Charlie
exit

le résultat est :

Student 'Alice' added successfully.
Student 'Bob' added successfully.
Grade 90 added for student 'Alice'.
Grade 85 added for student 'Alice'.
Grade 75 added for student 'Bob'.
Average grade of 'Alice': 87.50
Average grade of 'Bob': 75.00
Student 'Charlie' not found.
Goodbye!

Essayez vous-même

extends Node

# Chaque étudiant : nom -> {"age": int, "grades": Array, "courses": un ensemble de noms de cours}
var student_records := {}

func _ready():
	while true:
		var parts := Array(OS.read_string_from_stdin().split(" ", false))
		match parts:
			["add", var student, var age, ..]:
				add_student(student, int(age), parts.slice(3))
			["grade", var student, var grade]:
				add_grade(student, int(grade))
			["enrolled", var student, var course]:
				print(is_enrolled(student, course))
			["show"]:
				print(student_records)
			["exit"]:
				print("Goodbye!")
				break

func add_student(student_name: String, age: int, courses: Array) -> void:
	if student_records.has(student_name):
		print("Student '%s' already exists." % student_name)
		return
	var course_set := {}
	for course in courses:
		course_set[course] = true
	student_records[student_name] = {"age": age, "grades": [], "courses": course_set}
	print("Student '%s' added successfully." % student_name)

func add_grade(student_name: String, grade: int) -> void:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return
	student_records[student_name]["grades"].append(grade)
	print("Grade %d added for student '%s'." % [grade, student_name])

func is_enrolled(student_name: String, course: String) -> bool:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return false
	return student_records[student_name]["courses"].has(course)