Fonctions lambda, partie 2

Fait partie de la section Logique et flux d’exécution du Journey GDScript de Coddy. Leçon 55 sur 78.

Une lambda sur une seule ligne peut choisir son résultat à l’aide de l’opérateur ternaire, value_if_true if condition else value_if_false :

var check_age = func(age): return "Adult" if age >= 18 else "Minor"
print(check_age.call(20)) # Adult

Pour plus de deux cas, enchaîne un deuxième ternaire après else, ou écris la lambda sous forme de bloc avec if et elif :

var grade = func(score):
	if score == 100:
		return "Perfect"
	elif score >= 60:
		return "Pass"
	return "Fail"
print(grade.call(75)) # Pass

Comme une lambda est une valeur, tu peux la passer à une fonction. Déclare le paramètre avec le type Callable et exécute-la avec call() :

func apply_twice(fn: Callable, value):
	return fn.call(fn.call(value))

print(apply_twice(func(n): return n + 3, 1)) # 7

Une fonction nommée peut être passée de la même manière : écris son nom sans parenthèses, comme dans apply_twice(double, 5).

Les méthodes intégrées prennent également des fonctions. sort_custom() trie un tableau à l’aide d’une fonction lambda qui reçoit deux éléments et renvoie true lorsque le premier doit venir en premier :

var scores = [40, 90, 75]
scores.sort_custom(func(a, b): return a > b)
print(scores) # [90, 75, 40]

Une lambda peut lire les variables locales qui l’entourent, mais elle en copie les valeurs au moment de sa création. Modifier une telle variable par la suite n’a aucun effet sur la lambda, et lui affecter une valeur à l’intérieur de la lambda ne modifie pas la variable à l’extérieur.

Défi

Facile

Le programme lit un nombre entier. Créez une fonction lambda et stockez-la dans une variable nommée categorize_number. Elle prend un nombre et renvoie :

Positive si le nombre est supérieur à 0
Zero si le nombre est égal à 0
Negative si le nombre est inférieur à 0

Appelez-la avec le nombre lu et affichez le résultat. Pour l’entrée 10, la sortie est :

Positive

Essayez vous-même

extends Node

func _ready():
	var number := int(OS.read_string_from_stdin())
	# Créez la fonction lambda categorize_number ici

	# Appelez-la avec number et affichez le résultat