Meilleurs étudiants

Fait partie de la section Logique et flux d’exécution du Journey GDScript de Coddy. Leçon 48 sur 78.

Défi

Facile

Enfin, trouve les meilleurs étudiants. Conserve tout ce que tu as écrit dans les étapes précédentes.

1. La fonction. Sous les autres fonctions, écris filter_top_students(threshold: float) -> Array. Elle renvoie un tableau contenant les noms des étudiants dont la note moyenne est supérieure au seuil, dans l’ordre où ils ont été ajoutés. Récupère chaque moyenne avec calculate_average_grade() ; un étudiant sans notes a une moyenne de 0.0.

2. La commande. Ajoute une branche pour top <threshold>, comme top 80, au-dessus de ["show"]. Elle convertit le seuil avec float() et affiche le tableau renvoyé par filter_top_students(). Pour les commandes

add Alice 20 Math Physics
add Bob 22 Math Biology
add Diana 23 Chemistry Physics
grade Alice 90
grade Alice 85
grade Bob 75
grade Diana 95
top 80
top 90
top 100
exit

la sortie est :

Student 'Alice' added successfully.
Student 'Bob' added successfully.
Student 'Diana' added successfully.
Grade 90 added for student 'Alice'.
Grade 85 added for student 'Alice'.
Grade 75 added for student 'Bob'.
Grade 95 added for student 'Diana'.
["Alice", "Diana"]
["Diana"]
[]
Goodbye!

Ton Student Records Manager combine maintenant les dictionnaires, les ensembles, les tableaux, les fonctions et match dans un seul programme.

Essayez vous-même

extends Node

# Chaque étudiant : nom -> {"age": int, "grades": Array, "courses": un ensemble de noms de cours}
var student_records := {}

func _ready():
	while true:
		var parts := Array(OS.read_string_from_stdin().split(" ", false))
		match parts:
			["add", var student, var age, ..]:
				add_student(student, int(age), parts.slice(3))
			["grade", var student, var grade]:
				add_grade(student, int(grade))
			["enrolled", var student, var course]:
				print(is_enrolled(student, course))
			["average", var student]:
				var average := calculate_average_grade(student)
				if average >= 0:
					print("Average grade of '%s': %.2f" % [student, average])
			["course", var course]:
				print(list_students_by_course(course))
			["show"]:
				print(student_records)
			["exit"]:
				print("Goodbye!")
				break

func add_student(student_name: String, age: int, courses: Array) -> void:
	if student_records.has(student_name):
		print("Student '%s' already exists." % student_name)
		return
	var course_set := {}
	for course in courses:
		course_set[course] = true
	student_records[student_name] = {"age": age, "grades": [], "courses": course_set}
	print("Student '%s' added successfully." % student_name)

func add_grade(student_name: String, grade: int) -> void:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return
	student_records[student_name]["grades"].append(grade)
	print("Grade %d added for student '%s'." % [grade, student_name])

func is_enrolled(student_name: String, course: String) -> bool:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return false
	return student_records[student_name]["courses"].has(course)

func calculate_average_grade(student_name: String) -> float:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return -1.0
	var grades: Array = student_records[student_name]["grades"]
	if grades.is_empty():
		return 0.0
	var total := 0
	for grade in grades:
		total += grade
	return float(total) / grades.size()

func list_students_by_course(course: String) -> Array:
	var students_in_course := []
	for student_name in student_records:
		if student_records[student_name]["courses"].has(course):
			students_in_course.append(student_name)
	return students_in_course