レジスタでの引数渡し
CoddyのAssemblyジャーニー「関数、スタック、文字列」セクションの一部。レッスン 11/33。
呼び出し規約とは、すべての関数が従う一連のルールです。引数をどこに渡すか、結果がどこに返されるか、関数がどのレジスタを変更してよいかを定めます。異なる人が書いたコードや、C コンパイラが生成したコードが互いに呼び出し合えるのは、同じルールに従っているからです。Linux x86-64 では、このルールは System V AMD64 と呼ばれます。
最初の6つの整数引数は、その順番でrdi、rsi、rdx、rcx、r8、r9に渡されます。関数は結果をraxで返します。area(3, 4)を呼び出すには:
mov rdi, 3 ; 第1引数: 幅
mov rsi, 4 ; 第2引数: 高さ
call area ; rax = 12ロックされた main.asm も同じルールに従います。このセクションの各課題では、Cプログラムが関数を呼び出すのと同じ方法で solve を呼び出すため、入力は rdi、rsi、rdx、rcx に渡され、あなたの答えは rax から読み取られます。
関数は別のファイルに置くことができます。ファイルの先頭にあるextern areaは、ラベルareaが別の場所で定義されていることをnasmに伝えます。定義しているファイルではglobal areaを指定し、リンカーが2つを結合します。
extern area
...
call areacallが実行されるとき、すべての引数はレジスタに入っている必要があります。引数はその場で計算できます。lea rdi, [rdi + rdx * 2]は、rdxに触れずに、1つの命令でrdiをrdi + 2 * rdxに設定します。
チャレンジ
簡単solve は、rdi で画像の幅、rsi で高さ、rdx で枠線のサイズ(すべて 0 から 100)を受け取ります。枠で囲んだ幅(幅 + 枠線の 2 倍)を rdi に、枠で囲んだ高さ(高さ + 枠線の 2 倍)を rsi に指定して area を呼び出し、その結果を rax で返してください。
例:入力が 3 4 1 の場合、プログラムは 30 を出力します。
コードは solution.asm に書いてください。ロックされている main.asm は入力を読み取り、solve を呼び出して rax の数値、または solve が変更した呼び出し元保存レジスタの名前を出力します。
lib.asm には max2、area、score、points があり、それぞれにコメントが付いています。このファイルはロックされています。
自分で試してみよう
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitこのレッスンには短いクイズがあります。レッスンを始めて解答し、進捗を記録しましょう。
関数、スタック、文字列のすべてのレッスン
自分で練習してみよう: Assemblyプレイグラウンド