Menu
CoddyTech

PUSHとPOP

CoddyのAssemblyジャーニー「関数、スタック、文字列」セクションの一部。レッスン 1/33。

スタックは、プログラムが値を一時的に保持するために使うメモリ領域です。レジスタ rsp(スタックポインター)には、スタックの最上部にある値のアドレスが格納されます。プログラムが開始すると、rsp はすでにスタック内を指しています。

pushは8バイトの値を先頭に置きます。push rdiはまずrspから8を引き、その後、rspの新しいアドレスにrdiを格納します。スタックは下方向に伸びます。つまり、pushするたびにrspはより低いアドレスに移動します。実際のアドレスは大きな数値なので、例では小さな数値を使います。

; rsp = 1000
push rdi        ; rsp = 992、rdi は 992 に格納される
push rsi        ; rsp = 984、rsi は 984 に格納される

popはスタックの一番上の値を取り出します。pop raxは、rspに格納されたアドレスにある8バイトをraxにコピーし、その後rspに8を加算します。

; rsp = 984
pop rax         ; rax = 984から取得した値、rsp = 992
pop rbx         ; rbx = 992から取得した値、rsp = 1000

pushとpopを使えば、3つ目のレジスタなしで2つのレジスタを入れ替えられます。最初のpopは、最後にpushした値を返します。

push rdi        ; rdiを保存する
push rsi        ; rsiをスタックの一番上に保存する
pop rdi         ; rdi = 元のrsi
pop rsi         ; rsi = 元のrdi

このセクションの課題では、Cプログラムが関数を呼び出すのと同じ方法で、あなたのコードを呼び出します。ロックされている main.asm は、入力を順に rdi、rsi、rdx、rcx に格納し、あなたの solve を呼び出して、rax に残した数値を出力します。各課題には、使用する入力が書かれています。これらのレジスタを使う理由は、第3章で説明します。

challenge icon

チャレンジ

簡単

solve は2つの数値を受け取ります。1つ目は rdi に、2つ目は rsi に入っています。2つの push 命令と2つの pop 命令でレジスタを入れ替え、その後 rdi - rsi を rax に返します。

例:入力が 3 10 の場合、プログラムは 7 を出力します。

コードは solution.asm に書いてください。ロックされている main.asm は入力を読み取り、solve を呼び出し、rax の数値を出力します。

自分で試してみよう

bits 64
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall

関数、スタック、文字列のすべてのレッスン

自分で練習してみよう: Assemblyプレイグラウンド