Menu
CoddyTech

大文字・小文字の変換

CoddyのAssemblyジャーニー「関数、スタック、文字列」セクションの一部。レッスン 23/33。

小文字のアルファベット 'a' から 'z' は97から122までで、大文字のアルファベット 'A' から 'Z' は65から90までです。大文字はすべて対応する小文字より32小さくなります。'a' の97は 'A' の65になります。

バイトを大文字にするには、'a'から'z'の範囲内であることを確認し、その後32を引きます。それ以外のバイト(大文字、数字、空白)はそのままです。

    cmp cl, 'a'
    jb .keep
    cmp cl, 'z'
    ja .keep
    sub cl, 32        ; 'h' が 'H' になる
.keep:

mov [rsi], clは、rcxの最下位バイトである1バイトを、rsiに格納されているアドレスに書き込みます。サイズはレジスタによって決まります。clは1バイトなので、1バイトが書き込まれます。

このレッスン以降、一部の課題では新しいテキストを作成します。solveは、rsiにある256バイトの空のバッファーのアドレスも受け取ります。そこにテキストを書き込み、その長さをraxで返してください。ロックされたmain.asmが、バッファーからそのバイト数分を出力します。

1つのインデックスで、テキストとバッファを同時にたどることができます。このループはテキストを変更せずにコピーし、最後にraxはその長さになります。

    xor eax, eax
.next:
    movzx ecx, byte [rdi + rax]
    test ecx, ecx
    jz .done
    mov [rsi + rax], cl
    inc rax
    jmp .next
.done:
challenge icon

チャレンジ

簡単

solveは、ゼロバイトで終わるテキストのアドレスをrdiで、空のバッファーのアドレスをrsiで受け取ります。すべての小文字aからzを大文字にし、それ以外のバイトは変更せずに、テキストをバッファーにコピーしてください。テキストの長さをraxで返してください。

例:入力がhelloの場合、プログラムはHELLOを出力します。

コードはsolution.asmに記述してください。ロックされたmain.asmは1行のテキストを読み込み、solveを呼び出して、バッファーの先頭からraxバイトを出力します。

自分で試してみよう

bits 64
section .data
    changed_rbx db 'solve changed rbx', 10
    changed_rbp db 'solve changed rbp', 10
    changed_r12 db 'solve changed r12', 10
    changed_r13 db 'solve changed r13', 10
    changed_r14 db 'solve changed r14', 10
    changed_r15 db 'solve changed r15', 10
section .bss
    input_buffer resb 257
    text_buffer resb 257
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jg .trim
    xor eax, eax
.trim:
    test rax, rax
    jz .ended
    movzx edx, byte [input_buffer + rax - 1]
    cmp dl, 10
    je .drop
    cmp dl, 13
    jne .ended
.drop:
    dec rax
    jmp .trim
.ended:
    mov byte [input_buffer + rax], 0
    mov rbx, 0x1111111111111111
    mov rbp, 0x2222222222222222
    mov r12, 0x3333333333333333
    mov r13, 0x4444444444444444
    mov r14, 0x5555555555555555
    mov r15, 0x6666666666666666
    lea rdi, [input_buffer]
    lea rsi, [text_buffer]
    xor eax, eax
    call solve
    mov rdx, 0x1111111111111111
    lea rsi, [changed_rbx]
    cmp rbx, rdx
    jne .changed
    mov rdx, 0x2222222222222222
    lea rsi, [changed_rbp]
    cmp rbp, rdx
    jne .changed
    mov rdx, 0x3333333333333333
    lea rsi, [changed_r12]
    cmp r12, rdx
    jne .changed
    mov rdx, 0x4444444444444444
    lea rsi, [changed_r13]
    cmp r13, rdx
    jne .changed
    mov rdx, 0x5555555555555555
    lea rsi, [changed_r14]
    cmp r14, rdx
    jne .changed
    mov rdx, 0x6666666666666666
    lea rsi, [changed_r15]
    cmp r15, rdx
    jne .changed
    cmp rax, 256
    jbe .length_ok
    mov eax, 256
.length_ok:
    mov byte [text_buffer + rax], 10
    lea rdx, [rax + 1]
    lea rsi, [text_buffer]
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall
.changed:
    mov eax, 1
    mov edi, 1
    mov edx, 18
    syscall
    jmp .exit

関数、スタック、文字列のすべてのレッスン

自分で練習してみよう: Assemblyプレイグラウンド