결승선

Coddy의 Godot 게임: 네온 서킷 코스 레슨. 20개 중 12번째.

state는 경주의 현재 상태를 나타냅니다:

const LAPS := 3
var state := "racing"

바퀴 수가 LAPS에 도달하면 경주가 끝납니다. 상태가 완료로 바뀌고, 자동차가 키 입력에 반응하지 않으며, 시간이 표시됩니다. 완료 상태에서는 경주가 더 이상 아무것도 하지 않습니다:

func finish_race() -> void:
	state = "done"
	car.active = false
	$HUD/Message.text = "Finished!\nTime %s" % clock(race_time)

car.gd에서 active는 키 입력을 읽을지 결정합니다. 스로틀과 조향을 0으로 시작하고, 활성 상태일 때만 입력을 읽습니다:

var throttle := 0.0
var steer := 0.0
if active:
	throttle = Input.get_axis("move_down", "move_up")
	steer = Input.get_axis("move_left", "move_right")

챌린지

중급

race.gd에서 LAPS, state와 var race_time := 0.0을 추가하고, 랩 시간처럼 매 프레임 값을 증가시키세요.
_physics_process의 시작 부분에 상태가 완료되었으면 반환하도록 작성하세요.
finish_lap에서 laps >= LAPS이면 finish_race()를 호출하세요.
HUD에 "Lap %d/%d" % [mini(laps + 1, LAPS), LAPS]를 표시하세요.
car.gd에서 var active := true를 추가하고, 활성 상태일 때만 키 입력을 읽으세요(부스트 버튼도 포함).

직접 해보기

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO
var boost_time := 0.0
var boost_charge := 0.0

@onready var track: Node2D = $"../Track"


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")
	if Input.is_action_just_pressed("action") and boost_charge >= 1.0:
		boost_charge = 0.0
		boost_time = 1.0
	boost_charge = minf(1.0, boost_charge + delta / 10.0)
	$"../HUD/Boost".scale.x = boost_charge

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)
	var top := max_speed
	var grip_now := grip
	if boost_time > 0.0:
		boost_time -= delta
		top = max_speed * 1.3
		velocity += forward * accel * delta
	for pad in get_tree().get_nodes_in_group("boost_pads"):
		if position.distance_to(pad.position) < 22.0:
			boost_time = maxf(boost_time, 0.4)
	for oil in get_tree().get_nodes_in_group("oil"):
		if position.distance_to(oil.position) < 20.0:
			grip_now = grip * 0.12
	if not track.is_on_road(position):
		top = max_speed * 0.45
		velocity *= 1.0 - 2.5 * delta

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip_now * delta)
	velocity *= 1.0 - drag * delta
	if velocity.length() > top:
		velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0 or boost_time > 0.0
	$Flame.visible = boost_time > 0.0