=B2-A2 renvoie le nombre de jours entre la date de A2 et la date plus récente de B2. Excel stocke chaque date sous forme d'un nombre entier de jours (2026-03-15 vaut 46096) : soustraire une date d'une autre donne donc les jours qui les séparent.
| A | B | C | |
|---|---|---|---|
| 1 | Ordered | Delivered | Days |
| 2 | 2026-03-02 | 2026-03-09 | 7 |
| 3 | 2026-03-05 | 2026-03-07 | 2 |
| 4 | 2026-03-10 | 2026-04-02 | 23 |
| 5 | 2026-03-28 | 2026-04-03 | 6 |
| 6 | 2026-12-29 | 2027-01-04 | 6 |
=B2-A2Les commandes ont pris 7, 2, 23, 6 et 6 jours. La soustraction gère seule les changements de mois et d'année : la dernière commande passe le Nouvel An et compte toujours 6 jours. Modifiez une date de livraison et le compte suit. Si la date la plus ancienne est en B, le résultat est négatif : -7 au lieu de 7.
La fonction JOURS
=JOURS(date_fin;date_début) fait la même soustraction, avec la date de fin en premier. JOURS s'appelle DAYS dans un Excel anglais ; le tableau affiche les formules sous cette forme, avec des virgules, mais vous pouvez aussi les taper comme dans un Excel français, avec des points-virgules : =JOURS(B2;A2). Elle donne les mêmes nombres que =B2-A2 ; la principale raison de la préférer est que son nom dit ce que fait la formule.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Start | End | B2-A2 | DAYS |
| 2 | 2026-01-15 | 2026-03-10 | 54 | 54 |
| 3 | 2026-02-01 | 2026-03-01 | 28 | 28 |
| 4 | 2024-02-01 | 2024-03-01 | 29 | 29 |
=JOURS(B2;A2)Février 2026 compte 28 jours et février 2024 en compte 29 : Excel connaît le calendrier, années bissextiles comprises. Attention à l'ordre des arguments : =JOURS(A2;B2) renvoie -54 pour la première ligne. JOURS demande Excel 2013 ou une version ultérieure ; la soustraction fonctionne partout.
Compter les jours en incluant la date de début et la date de fin
La soustraction compte les jours entre deux dates, c'est-à-dire le nombre de nuits. Une réservation du 6 au 10 juillet représente 4 nuits, mais une voiture louée du 6 au 10 juillet est payée pour 5 jours. Quand le premier et le dernier jour comptent tous deux, ajoutez 1.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | From | To | Nights | Days (both counted) |
| 2 | 2026-07-06 | 2026-07-10 | 4 | 5 |
| 3 | 2026-07-31 | 2026-08-01 | 1 | 2 |
=B2-A2+1Un seul jour, du 2026-07-06 au 2026-07-06, vaut 0 par soustraction et 1 avec le +1. C'est l'origine de la plupart des erreurs d'un jour dans les feuilles de dates : décidez de ce dont vous avez besoin avant de remplir la colonne.
Semaines, mois et années entre deux dates
Divisez les jours par 7 pour obtenir des semaines. Les mois et les années n'ont pas un nombre fixe de jours : utilisez DATEDIF, qui compte les mois et les années civils complets.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Start | End | Weeks | Full weeks | Months | Years |
| 2 | 2025-06-15 | 2026-09-30 | 67.4 | 67 | 15 | 1 |
| 3 | 2024-01-01 | 2026-01-01 | 104.4 | 104 | 24 | 2 |
=ENT((B2-A2)/7)Du 2025-06-15 au 2026-09-30, il y a 67.4 semaines, 67 semaines complètes, 15 mois complets et 1 année complète. DATEDIF demande la date la plus ancienne en premier et renvoie #NOMBRE! (en anglais #NUM!, le nom que montre le tableau) dans l'autre sens.
Jours ouvrés entre deux dates
Pour ne compter que du lundi au vendredi, utilisez NB.JOURS.OUVRES(début;fin) (NETWORKDAYS en anglais). La fonction compte la date de début et la date de fin quand ce sont des jours de semaine, et peut ignorer une liste de jours fériés passée en troisième argument. NB.JOURS.OUVRES et SERIE.JOUR.OUVRE traite des jours fériés et des autres week-ends.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Start | End | Calendar days | Working days |
| 2 | 2026-03-02 | 2026-03-13 | 12 | 10 |
| 3 | 2026-03-06 | 2026-03-09 | 4 | 2 |
=NB.JOURS.OUVRES(A2;B2)Du 2 au 13 mars 2026, il y a 12 jours en comptant les deux extrémités, dont 10 jours de semaine. Du vendredi au lundi suivant, il y a 4 jours et 2 jours ouvrés.
Exercice : délai de livraison
| A | B | C | |
|---|---|---|---|
| 1 | Ordered | Delivered | Days |
| 2 | 2026-05-18 | 2026-05-27 |
À vous : En C2, calculez combien de jours la commande a pris, de la date de commande en A2 à la date de livraison en B2.
Pourquoi le résultat s'affiche comme une date ou
Deux problèmes d'affichage reviennent souvent avec la soustraction de dates :
- Le résultat ressemble à une date (
1900-01-07, ou07/01/1900avec des paramètres français). La cellule a gardé un format date, donc 7 jours s'affichent comme le 7e jour du calendrier d'Excel. Sélectionnez les cellules et choisissez Accueil > Format de nombre > Standard. - La cellule se remplit de
#####. Le résultat est négatif (les dates sont inversées) et la cellule est au format date, qui ne peut pas être négatif. Inversez les dates, utilisez=ABS(B2-A2), ou passez la cellule au format Standard pour voir le nombre négatif.
Si le résultat est #VALEUR! (#VALUE!), l'une des cellules contient un texte qui ressemble seulement à une date, comme 15.03.2026 dans un Excel réglé sur les dates américaines. Vérifiez avec =ESTNUM(A2) : une vraie date renvoie VRAI.
Questions fréquentes
Comment calculer le nombre de jours entre deux dates dans Excel ?
Soustrayez la date la plus ancienne de la plus récente : =B2-A2. Excel stocke les dates sous forme de nombres de jours, donc le résultat est le nombre de jours qui les séparent. =JOURS(B2;A2) donne le même résultat.
Comment compter les jours en incluant la date de début et la date de fin ?
Ajoutez 1 : =B2-A2+1. Du 6 au 10 juillet, il y a 4 jours par soustraction (les nuits d'un séjour à l'hôtel) et 5 jours en comptant les deux extrémités (les jours d'une location).
Comment calculer le nombre de mois entre deux dates dans Excel ?
=DATEDIF(A2;B2;"M") compte les mois complets. Pour les années, utilisez "Y". DATEDIF demande la date la plus ancienne en premier.
Quelle est la différence entre JOURS et la soustraction de dates ?
Aucune dans le résultat : =JOURS(B2;A2) et =B2-A2 renvoient le même nombre de jours. JOURS prend la date de fin en premier et demande Excel 2013 ou une version ultérieure ; la soustraction fonctionne dans toutes les versions.
Comment calculer le nombre de semaines entre deux dates dans Excel ?
Divisez les jours par 7 : =(B2-A2)/7 donne des semaines avec une partie décimale, et =ENT((B2-A2)/7) les semaines complètes.
