=NBCAR(A2) renvoie le nombre de caractères de A2. Chaque caractère compte : lettres, chiffres, espaces, ponctuation et retours à la ligne. Hello world en a 11. Dans un Excel anglais, NBCAR s'appelle LEN ; le tableau affiche les formules sous cette forme anglaise, avec des virgules, mais vous pouvez aussi les taper comme dans un Excel français, avec des points-virgules : =NBCAR(A2).
| A | B | |
|---|---|---|
| 1 | Text | Characters |
| 2 | Hello world | 11 |
| 3 | Hello world | 13 |
| 4 | Excel | 5 |
| 5 | 0 |
=NBCAR(A2)A3 a une espace à chaque bout, donc elle compte 13. A5 est vide, et NBCAR d'une cellule vide vaut 0. La syntaxe a un seul argument : =NBCAR(texte), où texte est une cellule, une formule ou du texte entre guillemets.
NBCAR compte la valeur stockée, pas l'affichage
Pour les nombres et les dates, NBCAR compte la valeur qu'Excel stocke, qui n'est pas toujours ce que vous voyez :
| A | B | C | |
|---|---|---|---|
| 1 | Value | LEN | LEN of the display |
| 2 | $1,050.00 | 4 | 9 |
| 3 | 2026-03-15 | 5 | 10 |
=NBCAR(A2)A2 affiche $1,050.00 mais est stocké comme 1050, donc NBCAR renvoie 4. La date est stockée comme le numéro de série 46096, donc NBCAR renvoie 5. Pour compter les caractères tels qu'ils s'affichent, convertissez d'abord avec TEXTE, comme dans la colonne C.
Compter les mots d'une cellule
Excel n'a pas de fonction pour compter les mots. Les mots sont séparés par des espaces, donc comptez les espaces et ajoutez un. Passez d'abord par SUPPRESPACE, pour que les doubles espaces et les espaces aux extrémités ne comptent pas comme des mots :
| A | B | |
|---|---|---|
| 1 | Text | Words |
| 2 | The quick brown fox | 4 |
| 3 | two spaces | 2 |
| 4 | one | 1 |
| 5 | 0 |
=SI(SUPPRESPACE(A2)="";0;NBCAR(SUPPRESPACE(A2))-NBCAR(SUBSTITUE(SUPPRESPACE(A2);" ";""))+1)Le principe, pour The quick brown fox : le texte nettoyé a 19 caractères ; sans les espaces, 16. Trois espaces signifient quatre mots. Le SI placé devant fait qu'une cellule vide compte 0 mot au lieu de 1.
| A | B | |
|---|---|---|
| 1 | Sentence | Words |
| 2 | Payment received with thanks |
À vous : En B2, comptez les mots de A2. Les mots sont séparés par une seule espace.
Vérifier une limite de caractères
NBCAR permet de vérifier un texte par rapport à une limite : un titre de page de 60 caractères, un SMS de 160, un nom de produit de 30. Les caractères restants sont la limite moins NBCAR, et la mise en forme conditionnelle peut signaler les lignes qui dépassent :
| A | B | C | |
|---|---|---|---|
| 1 | Title | Characters | Left |
| 2 | Desk lamp, black | 16 | 14 |
| 3 | Ergonomic office chair with headrest | 36 | -6 |
| 4 | Monitor stand | 13 | 17 |
=NBCAR(A2)La règle =NBCAR($A2)>30 colore toute la ligne de chaque titre qui dépasse la limite. Le $ devant A fait que chaque colonne de la ligne regarde le titre. Raccourcissez A3 à 30 caractères et la couleur disparaît. Pour refuser un texte trop long dès la saisie, utilisez Données > Validation des données et réglez Autoriser sur Longueur du texte.
| A | B | |
|---|---|---|
| 1 | Name | Left |
| 2 | Wireless mouse |
À vous : Les noms de produits ont au plus 40 caractères. En B2, renvoyez le nombre de caractères qui restent pour le nom de A2.
Compter les caractères d'une plage
NBCAR travaille sur une cellule. Donnez-lui une plage à l'intérieur de SOMME : elle compte chaque cellule, puis SOMME les additionne :
| A | B | C | |
|---|---|---|---|
| 1 | Text | Method | Total |
| 2 | Apple | SUM | 15 |
| 3 | Pear | SUMPRODUCT | 15 |
| 4 | Banana |
=SOMME(NBCAR(A2:A4))=SOMME(NBCAR(A2:A4)) fonctionne telle quelle dans Excel 2021 et Microsoft 365. Dans Excel 2019 et les versions plus anciennes, elle demande Ctrl+Maj+Entrée (Cmd+Maj+Entrée sur un Mac), ou utilisez SOMMEPROD, qui gère les tableaux toute seule.
Pour compter un caractère précis dans une cellule, comme les virgules d'une liste, comparez la longueur avant et après sa suppression : =NBCAR(A2)-NBCAR(SUBSTITUE(A2;",";"")). La page sur SUBSTITUE en montre un exemple modifiable, y compris pour compter un mot entier.
Questions fréquentes
Comment compter les caractères d'une cellule Excel ?
=NBCAR(A2) renvoie le nombre de caractères de A2. Les espaces, la ponctuation et les retours à la ligne comptent tous. Pour ignorer les espaces en trop, comptez le texte nettoyé : =NBCAR(SUPPRESPACE(A2)).
Comment compter les mots d'une cellule dans Excel ?
Comptez les espaces et ajoutez un : =NBCAR(SUPPRESPACE(A2))-NBCAR(SUBSTITUE(SUPPRESPACE(A2);" ";""))+1. Entourez-la ainsi : =SI(SUPPRESPACE(A2)="";0;...) pour qu'une cellule vide compte 0 mot, et non 1.
Pourquoi NBCAR donne-t-elle un mauvais compte pour un nombre ou une date ?
NBCAR compte la valeur stockée, pas ce que la cellule affiche. #,##0.00"))` (forme anglaise).
Comment compter tous les caractères d'une plage ?
=SOMME(NBCAR(A2:A10)) dans Excel 2021 et Microsoft 365. Dans les versions plus anciennes, utilisez =SOMMEPROD(NBCAR(A2:A10)), qui fonctionne sans Ctrl+Maj+Entrée.
