=SOMME.SI.ENS(C2:C7;A2:A7;"North";B2:B7;"Apple") additionne les ventes de C2:C7 sur les lignes où la colonne A vaut North et la colonne B vaut Apple. La plage à additionner vient en premier, puis une paire plage et condition pour chaque condition. SOMME.SI.ENS s'appelle SUMIFS dans un Excel anglais ; le tableau affiche les formules sous cette forme, avec des virgules, mais vous pouvez aussi les taper comme dans un Excel français, avec des points-virgules : =SOMME.SI.ENS(C2:C7;A2:A7;"North";B2:B7;"Apple").
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Condition | Total | |
| 2 | North | Apple | 120 | North, Apple | 150 | |
| 3 | South | Pear | 45 | North, over 50 | 200 | |
| 4 | North | Pear | 80 | North | 230 | |
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Apple | 30 |
=SOMME.SI.ENS(C2:C7;A2:A7;"North";B2:B7;"Apple")Deux lignes sont à la fois North et Apple, 120 et 30, donc F2 affiche 150. F3 utilise la colonne des ventes à la fois comme plage de somme et comme plage de critères : les lignes North supérieures à 50. F4 n'a qu'une condition et fonctionne comme SOMME.SI. Mettez Apple en B4 et F2 augmente de 80.
Syntaxe de SOMME.SI.ENS
=SUMIFS(sum_range, criteria_range1, criteria1, [criteria_range2, criteria2], ...)
sum_range(somme_plage) correspond aux cellules à additionner, et vient en premier. Dans SOMME.SI, elle vient en dernier :=SOMME.SI(A2:A7;"North";C2:C7). Mélanger les deux ordres est une erreur fréquente avec SOMME.SI.ENS. Si vous copiez une SOMME.SI pour y ajouter une condition, placez la plage de somme au début.- Chaque condition est une paire : une plage et un critère, jusqu'à 127 paires. Les critères fonctionnent comme ceux de SOMME.SI :
"North",">50","*apple*","<>", ou une cellule reliée à un opérateur,">="&G2. - Une ligne n'est additionnée que si toutes les conditions sont vraies.
- Toutes les plages doivent avoir la même taille, sinon SOMME.SI.ENS renvoie
#VALEUR!(en anglais #VALUE!).
SOMME.SI.ENS fonctionne aussi avec une seule condition, et l'écrire ainsi permet d'ajouter plus tard une seconde condition sans réordonner les arguments.
SOMME.SI.ENS avec une période de dates
Pour totaliser un mois, ou n'importe quelle période, utilisez deux fois la colonne des dates : une fois avec la date de début, une fois avec la date de fin. Gardez les dates dans des cellules.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Date | Setting | Value | |
| 2 | North | Apple | 120 | 2026-01-05 | Start | 2026-02-01 | |
| 3 | South | Pear | 45 | 2026-01-12 | End | 2026-02-28 | |
| 4 | North | Pear | 80 | 2026-02-03 | Total | 135 | |
| 5 | East | Apple | 55 | 2026-02-18 | North only | 80 | |
| 6 | South | Apple | 200 | 2026-03-02 | |||
| 7 | North | Apple | 30 | 2026-03-20 |
=SOMME.SI.ENS(C2:C7;D2:D7;">="&G2;D2:D7;"<="&G3)Février compte deux commandes, 80 et 55, donc G4 affiche 135, et G5 ne garde que celle de North. Mettez 2026-03-31 en G3 pour inclure mars. Si les dates contiennent une heure, "<="&G3 s'arrête à 0:00 le dernier jour : utilisez "<"&G3+1 comme condition de fin pour compter les commandes passées plus tard ce jour-là.
Pour totaliser un mois entier à partir d'une seule date en cellule, laissez FIN.MOIS (EOMONTH en anglais) trouver le dernier jour : =SOMME.SI.ENS(C2:C7;D2:D7;">="&G2;D2:D7;"<="&FIN.MOIS(G2;0)).
SOMME.SI.ENS avec OU
Les conditions de SOMME.SI.ENS sont toujours reliées par ET. Pour North ou South, donnez à la condition de région une liste entre accolades : SOMME.SI.ENS renvoie un total par élément et SOMME (SUM en anglais) les additionne.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Condition | Total | |
| 2 | North | Apple | 120 | North or South | 475 | |
| 3 | South | Pear | 45 | North or South, Apple | 350 | |
| 4 | North | Pear | 80 | Two SUMIFS | 475 | |
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Apple | 30 |
F2 et F4 donnent toutes deux 475, tout sauf la ligne East. F3 combine le OU sur les régions avec un ET sur le produit. Ne placez la liste que sur un seul critère : deux listes dans une même SOMME.SI.ENS associent leurs éléments position par position au lieu d'essayer toutes les combinaisons.
SOMME.SI.ENS avec un critère vide : un filtre facultatif
Un rapport a souvent des cellules de filtre que le lecteur peut laisser vides pour dire "tout". Une cellule vide utilisée comme critère ne signifie pas "n'importe quoi" : Excel la lit comme 0, ce qui ne correspond à rien dans une colonne de texte. Remplacez-la par le caractère générique "*", qui correspond à n'importe quel texte. Choisissez une région et un produit dans les listes, ou effacez-les.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Filter | Value | ||
| 2 | North | Apple | 120 | Region | North | ||
| 3 | South | Pear | 45 | Product | |||
| 4 | North | Pear | 80 | Total | 230 | ||
| 5 | East | Apple | 55 | ||||
| 6 | South | Apple | 200 | ||||
| 7 | North | Apple | 30 |
=SOMME.SI.ENS(C2:C7;A2:A7;SI(G2="";"*";G2);B2:B7;SI(G3="";"*";G3))Avec North choisi et aucun produit, G4 additionne toutes les lignes North : 230. Choisissez Apple en G3 et le total tombe à 150 ; effacez G2 et il additionne Apple pour toutes les régions. "*" ne correspond qu'à du texte : la méthode vaut pour les colonnes de texte, et une colonne de nombres demande plutôt une fourchette, ">="&min et "<="&max.
Pour additionner les lignes où une colonne est vide ou remplie, utilisez "" et "<>" comme critères. Avec une date de paiement en colonne D, =SOMME.SI.ENS(C2:C7;A2:A7;"North";D2:D7;"") additionne les ventes North pas encore payées.
Exercice : SOMME.SI.ENS
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Condition | Total | |
| 2 | North | Apple | 120 | South, Apple | ||
| 3 | South | Pear | 45 | |||
| 4 | North | Pear | 80 | |||
| 5 | East | Apple | 55 | |||
| 6 | South | Apple | 200 | |||
| 7 | North | Apple | 30 | |||
| 8 | South | Apple | 75 |
À vous : Additionnez les ventes où la région est South et le produit Apple. Écrivez la formule en F2.
| A | B | C | D | E | F | G | |
|---|---|---|---|---|---|---|---|
| 1 | Region | Product | Sales | Date | Setting | Value | |
| 2 | North | Apple | 120 | 2026-01-05 | Start | 2026-01-10 | |
| 3 | South | Pear | 45 | 2026-01-12 | End | 2026-03-05 | |
| 4 | North | Pear | 80 | 2026-02-03 | Total | ||
| 5 | East | Apple | 55 | 2026-02-18 | |||
| 6 | South | Apple | 200 | 2026-03-02 | |||
| 7 | North | Apple | 30 | 2026-03-20 | |||
| 8 | North | Plum | 65 | 2026-03-01 |
À vous : Additionnez les ventes North datées de G2 à G3, les deux jours inclus. Écrivez la formule en G4.
SOMME.SI.ENS, SOMME.SI ou SOMMEPROD
| Besoin | Fonction |
|---|---|
| Une seule condition | SOMME.SI(plage;critère;somme_plage) ou SOMME.SI.ENS avec une paire |
| Plusieurs conditions, toutes vraies | SOMME.SI.ENS(somme_plage;plage1;critère1;plage2;critère2) |
| L'une de plusieurs valeurs d'une même colonne | SUM(SUMIFS(sum_range,range,{"a","b"})) (forme anglaise) |
| Une condition sur un calcul (mois d'une date, une colonne comparée à une autre, prix multiplié par la quantité) | SOMMEPROD |
| Les mêmes conditions, mais un comptage | NB.SI.ENS |
Si une SOMME.SI.ENS renvoie 0, vérifiez chaque condition séparément avec NB.SI.ENS sur les mêmes plages : la condition dont le compte vaut 0 est celle qui ne correspond jamais, en général à cause d'une espace finale, d'un nombre stocké sous forme de texte ou d'une cellule écrite entre les guillemets (">=G2" au lieu de ">="&G2).
Questions fréquentes
Quelle est la différence entre SOMME.SI et SOMME.SI.ENS ?
SOMME.SI prend une seule condition et place la plage de somme en dernier : =SOMME.SI(A2:A7;"North";C2:C7). SOMME.SI.ENS prend autant de conditions que nécessaire et place la plage de somme en premier : =SOMME.SI.ENS(C2:C7;A2:A7;"North";B2:B7;"Apple"). Avec une seule condition, les deux donnent le même total.
Comment utiliser SOMME.SI.ENS avec une période de dates ?
Utilisez deux fois la colonne des dates, avec un début et une fin : =SOMME.SI.ENS(C2:C7;D2:D7;">="&G2;D2:D7;"<="&G3) additionne les ventes datées de G2 à G3, bornes incluses.
SOMME.SI.ENS peut-elle utiliser une logique OU ?
Pas directement : ses conditions sont reliées par ET. Donnez à un critère une liste et additionnez les résultats. En forme anglaise : =SUM(SUMIFS(C2:C7,A2:A7,{"North","South"})) totalise North et South.
Pourquoi SOMME.SI.ENS renvoie-t-elle #VALEUR! ?
La plage de somme et les plages de critères n'ont pas la même taille, par exemple C2:C7 avec A2:A8. Contrairement à SOMME.SI, SOMME.SI.ENS ne les redimensionne pas : chaque plage doit avoir le même nombre de lignes et de colonnes.
Comment rendre un critère de SOMME.SI.ENS facultatif ?
Remplacez une cellule de filtre vide par le caractère générique "*", qui correspond à n'importe quel texte : =SOMME.SI.ENS(C2:C7;A2:A7;SI(G2="";"*";G2)). Quand G2 est vide, toutes les régions sont incluses.
