La formule du pourcentage d'augmentation dans Excel est =(nouveau-ancien)/ancien. Avec la valeur de l'an dernier en B2 et celle de cette année en C2, tapez =(C2-B2)/B2 et mettez la cellule au format pourcentage. Un résultat positif est une hausse, un résultat négatif une baisse.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Product | Last year | This year | Change |
| 2 | Coffee | $12,400 | $14,880 | 20.0% |
| 3 | Tea | $8,600 | $7,740 | -10.0% |
| 4 | Juice | $5,200 | $5,460 | 5.0% |
| 5 | Water | $3,100 | $4,650 | 50.0% |
=(C2-B2)/B2Coffee a progressé de 20 % et Tea a baissé de 10 %, affiché -10.0%. Water a progressé de 50 %. Modifiez un nombre de la colonne C et le pourcentage se met à jour. Les parenthèses comptent : sans elles, =C2-B2/B2 divise d'abord et soustrait 1 des ventes de cette année.
Deux façons d'écrire la même formule
=(C2-B2)/B2 the change divided by the old value
=C2/B2-1 the new value as a share of the old, minus 100%
La première divise l'écart par l'ancienne valeur ; la seconde prend la nouvelle valeur comme part de l'ancienne, moins 100 %. Les deux donnent le même résultat. La première reprend la définition, elle est donc plus facile à vérifier plus tard. Dans les deux cas, on divise toujours par l'ancienne valeur. Diviser par la nouvelle est l'erreur la plus fréquente, et elle donne un autre nombre : de 80 à 100, c'est +25 %, mais 20 divisé par 100 donne 20 %.
Quand aucun des deux nombres n'est l'ancien, par exemple deux magasins comparés côte à côte, divisez plutôt l'écart par la moyenne des deux. C'est l'écart relatif, et pour 80 et 100 il donne 22,2 % quel que soit l'ordre :
=ABS(B2-C2)/AVERAGE(B2,C2)
Dans un Excel français, où AVERAGE s'appelle MOYENNE : =ABS(B2-C2)/MOYENNE(B2;C2). Les formules du tableau peuvent aussi être tapées ainsi, en français avec des points-virgules.
Évolution d'un mois sur l'autre
Pour une liste dans le temps, comparez chaque ligne à celle du dessus. Le premier mois n'a rien à quoi se comparer, donc la formule commence à la deuxième ligne.
| A | B | C | |
|---|---|---|---|
| 1 | Month | Visitors | Change |
| 2 | Jan | 4200 | |
| 3 | Feb | 4620 | 10.0% |
| 4 | Mar | 4389 | -5.0% |
| 5 | Apr | 5047 | 15.0% |
| 6 | May | 4795 | -5.0% |
| 7 | Jun | 5754 | 20.0% |
=(B3-B2)/B2Février est en hausse de 10 % sur janvier et mars en baisse de 5 %. Pour comparer chaque mois à janvier, verrouillez la base avec des dollars : =(B3-$B$2)/$B$2. Les références absolues expliquent le $.
Taux d'évolution à partir de zéro
Quand l'ancienne valeur est 0, la formule divise par zéro et renvoie #DIV/0!. Une hausse à partir de rien n'a pas de pourcentage : décidez ce que la cellule doit afficher à la place et testez ce cas.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Product | Last year | This year | Plain | Checked |
| 2 | Coffee | 12400 | 14880 | 20.0% | 20.0% |
| 3 | Cocoa | 0 | 2100 | #DIV/0! | new |
| 4 | Soda | 0 | 640 | #DIV/0! | new |
=(C2-B2)/B2D3 et D4 affichent #DIV/0! ; la colonne vérifiée affiche "new". En français, sa formule s'écrit =SI(B2=0;"new";(C2-B2)/B2) (SI est IF en anglais). =SIERREUR((C2-B2)/B2;"new") donne ici le même résultat, mais masque aussi de vraies erreurs, comme du texte dans la colonne des ventes. La page sur l'erreur de division par zéro traite le sujet en général.
Exercice : écrire le taux d'évolution
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Item | Old price | New price | Change |
| 2 | Bread | $2.40 | $2.76 |
À vous : En D2, calculez le taux d'évolution de l'ancien prix en B2 au nouveau prix en C2. La cellule est déjà au format pourcentage.
Taux d'évolution ou points de pourcentage
Quand les valeurs sont elles-mêmes des pourcentages, deux réponses différentes portent le nom d'"évolution". Un taux de conversion qui passe de 4 % à 5 % a augmenté de 1 point de pourcentage, et il a augmenté de 25 %.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Page | Before | After | Points | Percent change |
| 2 | Signup | 4.0% | 5.0% | 1.0% | 25.0% |
=C2-B2D2 soustrait les taux et affiche 1.0%, que vous présenteriez comme "1 point de pourcentage". E2 affiche 25.0%. Précisez ce que vous voulez dire, car "le taux a augmenté de 1 %" peut signifier l'un ou l'autre.
Anciennes valeurs négatives
Quand l'ancienne valeur est négative, comme une perte qui devient un bénéfice, la formule simple donne le mauvais signe : de -200 à 100, =(C2-B2)/B2 renvoie -150 %. Divisez plutôt par la valeur absolue de l'ancien nombre :
=(C2-B2)/ABS(B2)
De -200 à 100, cette formule renvoie 150 %, une hausse. Pour une croissance sur plusieurs années, un taux annuel moyen est plus utile qu'un seul grand pourcentage : =(C2/B2)^(1/5)-1 transforme une évolution sur cinq ans en taux de croissance annuel composé (TCAC).
Questions fréquentes
Quelle est la formule du pourcentage d'augmentation dans Excel ?
=(C2-B2)/B2, où B2 est l'ancienne valeur et C2 la nouvelle, avec la cellule au format pourcentage. =C2/B2-1 donne le même résultat. De 80 à 100, le résultat est 25 %.
Comment calculer un pourcentage de baisse dans Excel ?
Avec la même formule, =(C2-B2)/B2. Quand la nouvelle valeur est plus petite, le résultat est négatif : de 100 à 80, il vaut -20 %. Excel n'a pas de formule séparée pour la baisse.
Comment calculer un taux d'évolution quand l'ancienne valeur est 0 ?
Une évolution à partir de 0 n'a pas de pourcentage, et =(C2-B2)/B2 renvoie #DIV/0!. Affichez autre chose dans ce cas : =SI(B2=0;"n/a";(C2-B2)/B2).
Comment calculer un taux d'évolution avec des nombres négatifs ?
Divisez par la valeur absolue de l'ancien nombre : =(C2-B2)/ABS(B2). Une perte de -200 qui devient un bénéfice de 100 affiche alors +150 %, une hausse, au lieu du -150 % trompeur que donne la formule simple.
