Despeja el muro

Parte de la sección Proyectos del Journey de Godot de Coddy. Lección 9 de 33.

El último paso es una forma de ganar: rompe todos los ladrillos.

Cuenta los ladrillos que quedan. Empieza en 40 y resta uno cada vez que llega brick_broken. Cuando llegue a cero, la pared estará despejada:

bricks_left -= 1
if bricks_left == 0:
	$HUD/Message.text = "You Win!"
	get_tree().paused = true

Resta uno antes de comprobar si es cero. Si compruebas primero, la comprobación verá 1 con el último ladrillo y nunca verá 0.

La tecla Enter desde Game Over también inicia una partida nueva aquí. Tu Breakout está completo.

Desafío

Intermedio

En main.gd:

Añade var bricks_left = 40.
Por cada ladrillo que se rompa, resta uno.
Cuando no quede ninguno, muestra You Win! en $HUD/Message y pausa el juego.

Pruébalo tú mismo

extends Node2D

const BRICK = preload("res://brick.tscn")
const COLORS = [Color(1, 0.42, 0.42), Color(1, 0.78, 0.34), Color(0.49, 0.95, 0.75), Color(0.369, 0.635, 1), Color(0.75, 0.82, 0.95)]

var score = 0
var lives = 3

func _ready():
	for row in 5:
		for column in 8:
			var brick = BRICK.instantiate()
			brick.position = Vector2(68 + column * 72, 60 + row * 26)
			brick.color = COLORS[row]
			add_child(brick)
	$Ball.brick_broken.connect(_on_brick_broken)
	$HUD/Score.text = "Score: 0"
	$Ball.missed.connect(_on_missed)
	$HUD/Lives.text = "Lives: 3"

func _process(delta):
	if get_tree().paused and Input.is_action_just_pressed("action"):
		get_tree().paused = false
		get_tree().reload_current_scene()

func _on_brick_broken():
	score += 10
	$HUD/Score.text = "Score: %d" % score

func _on_missed():
	lives -= 1
	$HUD/Lives.text = "Lives: %d" % lives
	if lives == 0:
		$HUD/Message.text = "Game Over"
		get_tree().paused = true