Lớp và phương thức trừu tượng

Thuộc phần Lập trình hướng đối tượng trong hành trình GDScript của Coddy. Bài học 23 trên 65.

Một số lớp chỉ tồn tại để được mở rộng. Hình nào cũng có diện tích, nhưng bạn không thể tính diện tích cho đến khi biết hình đó là hình tròn hay hình chữ nhật. Đánh dấu lớp như vậy bằng @abstract, ở dòng phía trên class_name:

# shape.gd
@abstract
class_name Shape
extends RefCounted

@abstract func area() -> float
@abstract func perimeter() -> float

func describe() -> String:
	return "Area %.1f, perimeter %.1f" % [area(), perimeter()]

Một @abstract func có chữ ký nhưng không có phần thân: không có dấu hai chấm và không có code nào sau đó. Nó quy định rằng mọi lớp con phải cung cấp phương thức này. describe() là một phương thức thông thường; các lớp con kế thừa phương thức này và phương thức có thể gọi các phương thức trừu tượng ngay từ đầu.

Bạn không thể tạo đối tượng từ một lớp trừu tượng. Shape.new() khiến chương trình dừng trước khi bắt đầu với lỗi Parse Error: Cannot construct abstract class "Shape".

Một lớp con tự cài đặt mọi phương thức trừu tượng là một lớp thông thường:

# rectangle.gd
class_name Rectangle
extends Shape

var width: float
var height: float

func _init(w: float, h: float) -> void:
	width = w
	height = h

func area() -> float:
	return width * height

func perimeter() -> float:
	return 2 * (width + height)

var rect := Rectangle.new(4.0, 6.0)
print(rect.describe())

Area 24.0, perimeter 20.0

Nếu một lớp con bỏ sót một phương thức, Godot sẽ báo lỗi trước khi chạy: Class "Square" must implement "Shape.perimeter()" and other inherited abstract methods or be marked as "@abstract". Vì vậy, mọi đối tượng bạn có thể tạo đều có area() và perimeter().

Lớp trừu tượng vẫn có thể có biến và hàm khởi tạo _init(). Các lớp con gọi nó bằng super() như thường lệ.

Thử thách

Dễ

Một cửa hàng chấp nhận hai phương thức thanh toán. Mỗi khoản thanh toán có số tiền và biên lai, nhưng phí và tên phương thức tùy thuộc vào phương thức đó.

Tạo PaymentMethod thành lớp trừu tượng và khai báo hai phương thức trừu tượng: fee() -> float và method_name() -> String. Viết receipt(), hàm này trả về NAME: paid AMOUNT, fee FEE, total TOTAL với hai chữ số thập phân cho mỗi số (tổng là số tiền cộng với phí).
CreditCard: phí bằng 3% số tiền (amount * 0.03), còn tên phương thức là Credit card.
BankTransfer: phí là 1.5, hoặc 0.0 khi số tiền từ 100 trở lên, còn tên phương thức là Bank transfer.

Các lớp con sử dụng hàm khởi tạo của PaymentMethod. Code được cung cấp đọc số lượng khoản thanh toán, sau đó đọc mỗi khoản trên một dòng: card AMOUNT hoặc transfer AMOUNT. Code in ra từng biên lai và tổng phí. Với card 50 và transfer 120, kết quả in ra là:

Credit card: paid 50.00, fee 1.50, total 51.50
Bank transfer: paid 120.00, fee 0.00, total 120.00
Total fees: 1.50

Đặt code của bạn trong payment_method.gd, credit_card.gd và bank_transfer.gd. main.gd chứa code đầu vào/đầu ra được cung cấp và bạn không thể chỉnh sửa tệp này.

Tự làm thử

extends Node

func _ready():
	# Đoạn code đầu vào/đầu ra đã cho: giữ nguyên
	var count := int(OS.read_string_from_stdin())
	var total_fees := 0.0
	for i in count:
		var p := OS.read_string_from_stdin().split(" ")
		var payment: PaymentMethod
		if p[0] == "card":
			payment = CreditCard.new(float(p[1]))
		else:
			payment = BankTransfer.new(float(p[1]))
		print(payment.receipt())
		total_fees += payment.fee()
	print("Total fees: %.2f" % total_fees)