Mẫu tổng hợp

Thuộc phần Lập trình hướng đối tượng trong hành trình GDScript của Coddy. Bài học 55 trên 65.

Mẫu Composite tạo ra các cây trong đó một đối tượng riêng lẻ và một nhóm đối tượng có cùng các phương thức, nhờ đó code có thể xem cả nhóm như một mục duy nhất. Một chiếc túi chứa các món đồ, một chiếc túi có thể chứa những chiếc túi khác, và bạn có thể hỏi trọng lượng của bất kỳ chiếc túi nào theo cùng một cách.

Cả hai loại đều có chung một lớp cha trừu tượng:

# entry.gd
@abstract
class_name Entry
extends RefCounted

var entry_name: String

@abstract func get_weight() -> int
@abstract func display(indent: String) -> void

Lá là một mục đơn lẻ:

# item.gd
class_name Item
extends Entry

var weight: int

func _init(n: String, w: int) -> void:
	entry_name = n
	weight = w

func get_weight() -> int:
	return weight

func display(indent: String) -> void:
	print(indent, entry_name, " (", weight, ")")

Cấu trúc tổng hợp chứa các mục khác và lấy câu trả lời bằng cách hỏi từng mục. Một túi tự nó nặng 1:

# bag.gd
class_name Bag
extends Entry

var contents: Array[Entry] = []

func _init(n: String) -> void:
	entry_name = n

func add(entry: Entry) -> void:
	contents.append(entry)

func get_weight() -> int:
	var total := 1
	for entry in contents:
		total += entry.get_weight()
	return total

func display(indent: String) -> void:
	print(indent, entry_name, " [", get_weight(), "]")
	for entry in contents:
		entry.display(indent + "  ")

# main.gd
var pouch := Bag.new("Pouch")
pouch.add(Item.new("Gem", 2))
var backpack := Bag.new("Backpack")
backpack.add(Item.new("Sword", 8))
backpack.add(pouch)
backpack.display("")

Backpack [12]
  Sword (8)
  Pouch [3]
    Gem (2)

Bag.get_weight() không bao giờ kiểm tra một mục là đồ vật hay túi: hàm gọi cùng một phương thức trên từng mục, và một túi bên trong sẽ trả lời bằng cách hỏi các mục bên trong nó. Đệ quy đó duyệt toàn bộ cây, dù cây sâu đến đâu.

Các liên kết chỉ đi theo một chiều, từ túi đến các mục bên trong. Nếu mỗi mục cũng lưu thông tin về chiếc túi chứa nó, mỗi chiếc túi và các mục bên trong sẽ trỏ đến nhau, tạo thành một vòng tham chiếu không bao giờ được giải phóng. Khi một mục cần biết nó nằm ở đâu, hãy truyền thông tin đó xuống dưới làm đối số, giống như cách display() truyền độ thụt lề.

Thử thách

Trung bình

Xây dựng cây thư mục bằng mẫu Composite. DiskEntry (disk_entry.gd) khai báo get_size(), count_files() và list_lines(indent). Hãy viết:

FileEntry: kích thước của nó là size của chính nó, nó được tính là 1 tệp, và list_lines() in ra phần thụt lề, rồi đến NAME (SIZE KB).
FolderEntry: add(entry) lưu một mục con. Kích thước của nó là tổng kích thước các mục con, số tệp là tổng số tệp của chúng, và list_lines() in ra phần thụt lề, rồi đến NAME/ (SIZE KB), sau đó liệt kê từng mục con với phần thụt lề cộng thêm hai dấu cách.

Code được cung cấp tạo cây từ đầu vào (số dòng tiếp theo, rồi đến folder NAME, file NAME SIZE hoặc end, để đóng thư mục hiện tại), liệt kê cây và in ra tổng số. Với một thư mục Root chứa notes.txt (4 KB) và một thư mục Music có song.mp3 (300 KB), đầu ra là:

Root/ (304 KB)
  notes.txt (4 KB)
  Music/ (300 KB)
    song.mp3 (300 KB)
Total: 304 KB, files: 2

Code của bạn nằm trong file_entry.gd và folder_entry.gd. main.gd chứa code đầu vào/đầu ra được cung cấp và bạn không thể chỉnh sửa tệp này.

Tự làm thử

extends Node

func _ready():
	# Đoạn code đầu vào/đầu ra đã cho: giữ nguyên
	var open_folders: Array[FolderEntry] = []
	var root: FolderEntry = null
	var count := int(OS.read_string_from_stdin())
	for i in count:
		var parts := OS.read_string_from_stdin().split(" ")
		match parts[0]:
			"folder":
				var folder := FolderEntry.new(parts[1])
				if open_folders.is_empty():
					root = folder
				else:
					open_folders.back().add(folder)
				open_folders.append(folder)
			"file":
				open_folders.back().add(FileEntry.new(parts[1], int(parts[2])))
			"end":
				open_folders.pop_back()
	root.list_lines("")
	print("Total: %d KB, files: %d" % [root.get_size(), root.count_files()])

Tự kiểm tra

Bài học này có một bài trắc nghiệm ngắn. Bắt đầu bài học để trả lời và theo dõi tiến độ.

Tất cả bài học trong Lập trình hướng đối tượng

3Kế thừa

Kế thừa cơ bản Từ khóa super Ghi đè phương thức Chuỗi kế thừa Kiểm tra kiểu bằng is Tổng kết: phân cấp nhân viên

6Phương thức đặc biệt

Giới thiệu về phương thức ảo Phương thức _to_string Trình lặp tùy chỉnh Ôn tập: danh sách tùy chỉnh

9Mẫu thiết kế, phần 1

Giới thiệu về mẫu thiết kế Mẫu Singleton Mẫu Factory Mẫu Observer Mẫu Strategy

12Thử thách cuối cùng

Nền tảng học trực tuyến Hệ thống ngân hàng Phát triển nhân vật trò chơi Dịch vụ cho thuê phương tiện

Tự luyện tập: Trình biên dịch GDScript online