Enum trong lớp

Thuộc phần Lập trình hướng đối tượng trong hành trình GDScript của Coddy. Bài học 44 trên 65.

Bạn có thể khai báo một enum bên trong lớp, cạnh các biến của lớp. Khi đó, các lựa chọn thuộc về lớp đó:

# weapon.gd
class_name Weapon
extends RefCounted

enum Kind { SWORD, BOW, STAFF }

var kind: Kind

func _init(weapon_kind: Kind) -> void:
	kind = weapon_kind

func is_ranged() -> bool:
	return kind == Kind.BOW or kind == Kind.STAFF

Bên trong weapon.gd, enum có tên là Kind. Trong mọi tệp khác, hãy viết tên lớp trước, Weapon.Kind.BOW, trong các giá trị, chú thích kiểu và mẫu match:

# blacksmith.gd
class_name Blacksmith
extends RefCounted

static func repair_cost(kind: Weapon.Kind) -> int:
	match kind:
		Weapon.Kind.SWORD:
			return 20
		Weapon.Kind.BOW:
			return 15
	return 30

Các tùy chọn vẫn là số: Weapon.new(Weapon.Kind.BOW).kind in ra 1. Bản thân enum hoạt động như một từ điển ánh xạ tên thành số:

print(Weapon.Kind.keys())       # ["SWORD", "BOW", "STAFF"]
print(Weapon.Kind.find_key(1))  # BOW
print(Weapon.Kind["STAFF"])     # 2
print(Weapon.Kind.size())       # 3
for kind in Weapon.Kind.values():
	print(Weapon.Kind.find_key(kind), ": ", Blacksmith.repair_cost(kind))

Vòng lặp in ra SWORD: 20, BOW: 15 và STAFF: 30. GDScript không kiểm tra xem một số có nằm trong các lựa chọn hay không: Weapon.new(7) tạo ra một vũ khí có kind là 7. Hãy truyền các lựa chọn có tên để code vẫn chính xác.

Enum mô tả một lớp nên nằm bên trong lớp đó, để người đọc biết Kind trong Weapon.Kind.BOW bắt nguồn từ đâu.

Thử thách

Dễ

Sắp xếp các bình thuốc bằng một enum trong lớp Potion.

Trong potion.gd, khai báo enum Kind { HEAL, MANA, POISON } và đặt kiểu của kind là Kind.
Potion.from_text(text, strength) là một hàm tĩnh, chuyển "MANA" thành Kind.MANA và trả về một bình thuốc mới.
describe() trả về HEAL potion: +20 HP, MANA potion: +15 MP hoặc POISON potion: -5 HP, sử dụng tên loại và độ mạnh.
Trong belt.gd, summary() trả về một dòng cho mỗi loại, theo thứ tự trong enum: HEAL: 2 (35 total), kèm số bình thuốc thuộc loại đó và tổng độ mạnh của chúng trong ngoặc đơn. Các loại không có bình thuốc vẫn có một dòng.

Code được cung cấp sẽ đọc số lượng bình thuốc tiếp theo (HEAL 20), thêm từng bình vào túi, in mô tả của bình rồi in phần tóm tắt. Với HEAL 20, POISON 5, HEAL 15, chương trình in ra:

Added HEAL potion: +20 HP
Added POISON potion: -5 HP
Added HEAL potion: +15 HP
HEAL: 2 (35 total)
MANA: 0 (0 total)
POISON: 1 (5 total)

Code của bạn nằm trong potion.gd và belt.gd. main.gd chứa code đầu vào/đầu ra được cung cấp và bạn không thể chỉnh sửa tệp này.

Tự làm thử

extends Node

func _ready():
	# Đoạn code đầu vào/đầu ra đã cho: giữ nguyên
	var belt := Belt.new()
	var count := int(OS.read_string_from_stdin())
	for i in count:
		var parts := OS.read_string_from_stdin().split(" ")
		var potion := Potion.from_text(parts[0], int(parts[1]))
		belt.add(potion)
		print("Added ", potion.describe())
	for line in belt.summary():
		print(line)

Tự kiểm tra

Bài học này có một bài trắc nghiệm ngắn. Bắt đầu bài học để trả lời và theo dõi tiến độ.

Tất cả bài học trong Lập trình hướng đối tượng

3Kế thừa

Kế thừa cơ bản Từ khóa super Ghi đè phương thức Chuỗi kế thừa Kiểm tra kiểu bằng is Tổng kết: phân cấp nhân viên

6Phương thức đặc biệt

Giới thiệu về phương thức ảo Phương thức _to_string Trình lặp tùy chỉnh Ôn tập: danh sách tùy chỉnh

9Mẫu thiết kế, phần 1

Giới thiệu về mẫu thiết kế Mẫu Singleton Mẫu Factory Mẫu Observer Mẫu Strategy

12Thử thách cuối cùng

Nền tảng học trực tuyến Hệ thống ngân hàng Phát triển nhân vật trò chơi Dịch vụ cho thuê phương tiện

Tự luyện tập: Trình biên dịch GDScript online