Argumente in Registern
Teil des Abschnitts Funktionen, Stack und Zeichenketten der Assembly-Journey von Coddy. Lektion 11 von 33.
Eine Aufrufkonvention ist die Menge der Regeln, auf die sich jede Funktion einigt: wohin die Argumente kommen, wo das Ergebnis zurückkommt und welche Register eine Funktion ändern darf. Von verschiedenen Personen geschriebener Code oder von einem C-Compiler erzeugter Code kann sich gegenseitig aufrufen, weil er denselben Regeln folgt. Unter Linux x86-64 heißen diese Regeln System V AMD64.
Die ersten sechs ganzzahligen Argumente werden der Reihe nach in rdi, rsi, rdx, rcx, r8 und r9 übergeben. Die Funktion gibt ihr Ergebnis in rax zurück. So rufst du area(3, 4) auf:
mov rdi, 3 ; erstes Argument: die Breite
mov rsi, 4 ; zweites Argument: die Höhe
call area ; rax = 12Die gesperrte main.asm folgt denselben Regeln: Jede Herausforderung in diesem Abschnitt hat dir ihre Eingaben in rdi, rsi, rdx und rcx bereitgestellt, weil sie solve so aufruft, wie ein C-Programm eine Funktion aufruft, und deine Antwort aus rax ausliest.
Eine Funktion kann sich in einer anderen Datei befinden. extern area am Anfang deiner Datei teilt nasm mit, dass das Label area an anderer Stelle definiert ist; die Datei, in der es definiert wird, kennzeichnet es mit global area, und der Linker fügt beide zusammen.
extern area
...
call areaJedes Argument muss sich in seinem Register befinden, wenn call ausgeführt wird. Du kannst ein Argument direkt berechnen: lea rdi, [rdi + rdx * 2] setzt rdi mit einer einzigen Instruktion auf rdi + 2 * rdx, ohne rdx zu verändern.
Aufgabe
Einfachsolve erhält die Breite eines Bildes in rdi, seine Höhe in rsi und eine Rahmenbreite in rdx (alle Werte von 0 bis 100). Rufe area mit der Breite einschließlich Rahmen (Breite + 2 × Rahmen) in rdi und der Höhe einschließlich Rahmen (Höhe + 2 × Rahmen) in rsi auf und gib das Ergebnis in rax zurück.
Beispiel: Bei der Eingabe 3 4 1 gibt das Programm 30 aus.
Schreibe deinen Code in solution.asm. Die gesperrte Datei main.asm liest die Eingabe ein, ruft solve auf und gibt die Zahl in rax oder den Namen eines callee-saved Registers aus, das solve verändert hat.
lib.asm enthält max2, area, score und points, jeweils mit einem Kommentar; die Datei ist gesperrt.
Probier es selbst
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitDiese Lektion enthält ein kurzes Quiz. Starte die Lektion, um es zu beantworten und deinen Fortschritt zu speichern.
Alle Lektionen in Funktionen, Stack und Zeichenketten
1Der Stack
PUSH und POPZuletzt hinein, zuerst herausEin Register sichernLesen mit [rsp]Rückblick: Rückgängig-Verlauf4Stack Frames und Rekursion
Lokale VariablenFrames mit RBPRekursionZwei rekursive AufrufeRückblick: Ziffernsumme3Die Aufrufkonvention
Argumente in RegisternRückgabewerteVom Aufrufer gesicherte RegisterVom Aufgerufenen gesicherte RegisterWiederholung: ScoreboardÜbe selbstständig: Assembly-Playground