Menu
CoddyTech

Bytes und ASCII

Teil des Abschnitts Funktionen, Stack und Zeichenketten der Assembly-Journey von Coddy. Lektion 21 von 33.

Ein Zeichen wird als ein Byte gespeichert: sein ASCII-Code. 'A' ist 65, 'a' ist 97, die Ziffer '0' ist 48 und ein Leerzeichen ist 32. Ein Text im Speicher ist eine Folge dieser Bytes, eines pro Zeichen.

In diesem Kapitel liest die gesperrte main.asm eine Textzeile und übergibt ihre Adresse in rdi an solve. Der Text endet mit einem Nullbyte, der Zahl 0, die von keinem Zeichen verwendet wird. Code, der den Text durchläuft, hält an, wenn er diese Null liest. C speichert seine Zeichenfolgen genauso.

movzx eax, byte [rdi] liest ein Byte und füllt den Rest von rax mit Nullen. Ein einfaches mov al, [rdi] ändert nur das niedrigste Byte und behält die alten oberen Bytes von rax bei, sodass ein anschließender Vergleich des gesamten rax schiefgehen kann.

movzx eax, byte [rdi]       ; rax = das erste Byte, für 'Hi' 72
movzx ecx, byte [rdi + 1]   ; rcx = das zweite Byte, 105

Jedes Zeichen ist ein Byte groß, daher befindet sich das nächste Zeichen an der nächsten Adresse: inc rdi oder über ein Indexregister in [rdi + rcx]. Diese Schleife endet am Nullbyte:

    xor ecx, ecx
.next:
    movzx eax, byte [rdi + rcx]
    test eax, eax
    jz .end
    inc rcx
    jmp .next
.end:

In NASM ist ein Zeichen in Anführungszeichen sein Code: cmp al, 'a' ist dieselbe Anweisung wie cmp al, 97. Anführungszeichen machen den Code leichter lesbar als die Zahl.

challenge icon

Aufgabe

Einfach

solve erhält die Adresse eines Textes in rdi; der Text endet mit einem Nullbyte. Gib in rax die Anzahl der Bytes vor dem Nullbyte zurück. Ein leerer Text ergibt 0.

Beispiel: Bei der Eingabe hello gibt das Programm 5 aus.

Schreibe deinen Code in solution.asm. Die gesperrte Datei main.asm liest eine Textzeile ein, ruft solve auf und gibt die Zahl in rax aus.

Probier es selbst

bits 64
section .data
    changed_rbx db 'solve changed rbx', 10
    changed_rbp db 'solve changed rbp', 10
    changed_r12 db 'solve changed r12', 10
    changed_r13 db 'solve changed r13', 10
    changed_r14 db 'solve changed r14', 10
    changed_r15 db 'solve changed r15', 10
section .bss
    input_buffer resb 257
    text_buffer resb 256
    output_buffer resb 32
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jg .trim
    xor eax, eax
.trim:
    test rax, rax
    jz .ended
    movzx edx, byte [input_buffer + rax - 1]
    cmp dl, 10
    je .drop
    cmp dl, 13
    jne .ended
.drop:
    dec rax
    jmp .trim
.ended:
    mov byte [input_buffer + rax], 0
    mov rbx, 0x1111111111111111
    mov rbp, 0x2222222222222222
    mov r12, 0x3333333333333333
    mov r13, 0x4444444444444444
    mov r14, 0x5555555555555555
    mov r15, 0x6666666666666666
    lea rdi, [input_buffer]
    lea rsi, [text_buffer]
    xor eax, eax
    call solve
    mov rdx, 0x1111111111111111
    lea rsi, [changed_rbx]
    cmp rbx, rdx
    jne .changed
    mov rdx, 0x2222222222222222
    lea rsi, [changed_rbp]
    cmp rbp, rdx
    jne .changed
    mov rdx, 0x3333333333333333
    lea rsi, [changed_r12]
    cmp r12, rdx
    jne .changed
    mov rdx, 0x4444444444444444
    lea rsi, [changed_r13]
    cmp r13, rdx
    jne .changed
    mov rdx, 0x5555555555555555
    lea rsi, [changed_r14]
    cmp r14, rdx
    jne .changed
    mov rdx, 0x6666666666666666
    lea rsi, [changed_r15]
    cmp r15, rdx
    jne .changed
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall
.changed:
    mov eax, 1
    mov edi, 1
    mov edx, 18
    syscall
    jmp .exit

Alle Lektionen in Funktionen, Stack und Zeichenketten

Übe selbstständig: Assembly-Playground