PUSH und POP
Teil des Abschnitts Funktionen, Stack und Zeichenketten der Assembly-Journey von Coddy. Lektion 1 von 33.
Der Stack ist ein Speicherbereich, den dein Programm verwendet, um Werte für kurze Zeit aufzubewahren. Das Register rsp (der Stackpointer) enthält die Adresse des obersten Werts auf dem Stack. Wenn dein Programm startet, zeigt rsp bereits auf den Stack.
push legt einen 8 Byte großen Wert oben auf den Stack. push rdi zieht zuerst 8 von rsp ab und speichert dann rdi an der neuen Adresse in rsp. Der Stack wächst nach unten: Jeder Push verschiebt rsp zu einer niedrigeren Adresse. Echte Adressen sind lange Zahlen, deshalb verwenden die Beispiele kleine Zahlen.
; rsp = 1000
push rdi ; rsp = 992, rdi wird an Adresse 992 gespeichert
push rsi ; rsp = 984, rsi wird an Adresse 984 gespeichertpop nimmt den obersten Wert herunter. pop rax kopiert die 8 Bytes an der in rsp angegebenen Adresse nach rax und addiert dann 8 zu rsp.
; rsp = 984
pop rax ; rax = der Wert von 984, rsp = 992
pop rbx ; rbx = der Wert von 992, rsp = 1000Mit Push und Pop lassen sich zwei Register ohne ein drittes vertauschen. Das erste Pop gibt den zuletzt gespeicherten Wert zurück:
push rdi ; rdi sichern
push rsi ; rsi oben auf dem Stapel sichern
pop rdi ; rdi = der alte Wert von rsi
pop rsi ; rsi = der alte Wert von rdiIn diesem Abschnitt rufen die Herausforderungen deinen Code so auf, wie ein C-Programm eine Funktion aufruft. Das gesperrte main.asm legt die Eingaben in dieser Reihenfolge in rdi, rsi, rdx und rcx ab, ruft dein solve auf und gibt die Zahl aus, die du in rax hinterlässt. Bei jeder Aufgabe steht, welche Eingaben sie verwendet. Kapitel 3 erklärt, warum diese Register verwendet werden.
Aufgabe
Einfachsolve erhält zwei Zahlen: die erste in rdi, die zweite in rsi. Tausche die beiden Register mit zwei push- und zwei pop-Anweisungen und gib dann rdi - rsi in rax zurück.
Beispiel: Bei der Eingabe 3 10 gibt das Programm 7 aus.
Schreibe deinen Code in solution.asm. Die gesperrte Datei main.asm liest die Eingabe, ruft solve auf und gibt die Zahl in rax aus.
Probier es selbst
bits 64
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscallAlle Lektionen in Funktionen, Stack und Zeichenketten
1Der Stack
PUSH und POPZuletzt hinein, zuerst herausEin Register sichernLesen mit [rsp]Rückblick: Rückgängig-Verlauf4Stack Frames und Rekursion
Lokale VariablenFrames mit RBPRekursionZwei rekursive AufrufeRückblick: ZiffernsummeÜbe selbstständig: Assembly-Playground