Frames mit RBP
Teil des Abschnitts Funktionen, Stack und Zeichenketten der Assembly-Journey von Coddy. Lektion 17 von 33.
Durch lokale Variablen, Pushes und Aufrufe bewegt sich rsp ständig, sodass [rsp + 8] an verschiedenen Stellen einer Funktion einen anderen Speicherplatz bedeuten kann. Ein Stackframe schafft einen festen Bezugspunkt: das Register rbp (den Basiszeiger).
Eine Funktion mit einem Stack-Frame beginnt mit drei Zeilen, dem Prolog:
push rbp ; rbp des Aufrufers sichern
mov rbp, rsp ; rbp markiert diesen Stack-Frame
sub rsp, 16 ; zwei lokale VariablenDie lokalen Variablen liegen unterhalb von rbp, bei [rbp - 8] und [rbp - 16]. Diese Adressen bezeichnen während der gesamten Funktion dieselben Speicherplätze, unabhängig davon, wie viele Werte du später auf den Stack legst.
Der Epilog macht den Prolog rückgängig. mov rsp, rbp entfernt alle lokalen Variablen auf einmal, und pop rbp gibt dem Aufrufer sein rbp zurück:
mov rsp, rbp ; lokale Variablen verwerfen
pop rbp ; das rbp des Aufrufers ist wiederhergestellt
retrbp wird vom aufgerufenen Funktionscode bewahrt. Daher sorgen das push am Anfang und das pop am Ende dafür, dass es für den Aufrufer unverändert bleibt. Oberhalb von rbp befinden sich das gespeicherte rbp bei [rbp] und die Rücksprungadresse bei [rbp + 8]. Andere Register, die vom aufgerufenen Funktionscode bewahrt werden und die du verwendest, kommen direkt nach dem Prolog auf den Stack und werden direkt vor mov rsp, rbp wieder entfernt:
push rbp
mov rbp, rsp
sub rsp, 16
push rbx
; ... die Funktion ...
pop rbx
mov rsp, rbp
pop rbp
retAufgabe
Einfachsolve erhält n (1 bis 50) in rdi. Verwende einen Stackframe mit zwei lokalen Variablen: [rbp - 8] für den bisher höchsten score und [rbp - 16] für dessen Level. Prüfe die Level von 1 bis n und behalte das erste Level mit dem höchsten Punktestand. Gib level * 100 + score in rax zurück.
Beispiel: Bei der Eingabe 5 gibt das Programm 509 aus.
Schreibe deinen Code in solution.asm. Die gesperrte Datei main.asm liest die Eingabe, ruft solve auf und gibt die Zahl in rax oder den Namen eines callee-saved Registers aus, das solve geändert hat.
lib.asm enthält max2, area, score und points, jeweils mit einem Kommentar; die Datei ist gesperrt.
Probier es selbst
bits 64
section .data
changed_rbx db 'solve changed rbx', 10
changed_rbp db 'solve changed rbp', 10
changed_r12 db 'solve changed r12', 10
changed_r13 db 'solve changed r13', 10
changed_r14 db 'solve changed r14', 10
changed_r15 db 'solve changed r15', 10
section .bss
input_buffer resb 256
output_buffer resb 32
values resq 4
section .text
global _start
extern solve
_start:
xor eax, eax
xor edi, edi
mov rsi, input_buffer
mov edx, 255
syscall
test rax, rax
jle .loaded
mov rsi, input_buffer
lea rdi, [input_buffer + rax]
xor ecx, ecx
.scan:
cmp rsi, rdi
jae .loaded
cmp ecx, 4
jae .loaded
movzx eax, byte [rsi]
cmp al, 32
jbe .space
mov r10, 1
cmp al, '-'
jne .number
mov r10, -1
inc rsi
.number:
xor eax, eax
.digit:
cmp rsi, rdi
jae .store
movzx edx, byte [rsi]
cmp dl, '0'
jb .store
cmp dl, '9'
ja .store
imul rax, rax, 10
sub edx, '0'
add rax, rdx
inc rsi
jmp .digit
.store:
imul rax, r10
mov [values + rcx * 8], rax
inc ecx
.space:
inc rsi
jmp .scan
.loaded:
mov rbx, 0x1111111111111111
mov rbp, 0x2222222222222222
mov r12, 0x3333333333333333
mov r13, 0x4444444444444444
mov r14, 0x5555555555555555
mov r15, 0x6666666666666666
mov rdi, [values]
mov rsi, [values + 8]
mov rdx, [values + 16]
mov rcx, [values + 24]
xor eax, eax
call solve
mov rdx, 0x1111111111111111
lea rsi, [changed_rbx]
cmp rbx, rdx
jne .changed
mov rdx, 0x2222222222222222
lea rsi, [changed_rbp]
cmp rbp, rdx
jne .changed
mov rdx, 0x3333333333333333
lea rsi, [changed_r12]
cmp r12, rdx
jne .changed
mov rdx, 0x4444444444444444
lea rsi, [changed_r13]
cmp r13, rdx
jne .changed
mov rdx, 0x5555555555555555
lea rsi, [changed_r14]
cmp r14, rdx
jne .changed
mov rdx, 0x6666666666666666
lea rsi, [changed_r15]
cmp r15, rdx
jne .changed
lea rsi, [output_buffer + 31]
mov byte [rsi], 10
mov ecx, 1
xor r8d, r8d
test rax, rax
jns .positive
mov r8d, 1
neg rax
.positive:
mov r9d, 10
.convert:
xor edx, edx
div r9
add dl, '0'
dec rsi
mov [rsi], dl
inc ecx
test rax, rax
jnz .convert
test r8d, r8d
jz .write
dec rsi
mov byte [rsi], '-'
inc ecx
.write:
mov edx, ecx
mov eax, 1
mov edi, 1
syscall
.exit:
mov eax, 60
xor edi, edi
syscall
.changed:
mov eax, 1
mov edi, 1
mov edx, 18
syscall
jmp .exitDiese Lektion enthält ein kurzes Quiz. Starte die Lektion, um es zu beantworten und deinen Fortschritt zu speichern.
Alle Lektionen in Funktionen, Stack und Zeichenketten
1Der Stack
PUSH und POPZuletzt hinein, zuerst herausEin Register sichernLesen mit [rsp]Rückblick: Rückgängig-Verlauf4Stack Frames und Rekursion
Lokale VariablenFrames mit RBPRekursionZwei rekursive AufrufeRückblick: ZiffernsummeÜbe selbstständig: Assembly-Playground