Menu
CoddyTech

Rückgabewerte

Teil des Abschnitts Funktionen, Stack und Zeichenketten der Assembly-Journey von Coddy. Lektion 12 von 33.

Eine Funktion gibt ihr Ergebnis in rax zurück. Der Aufrufer liest rax direkt nach dem call, bevor irgendetwas anderes den Wert ändert.

Das Schreiben einer eigenen Funktion folgt denselben Regeln: ein Label, Code, der seine Argumente aus rdi, rsi und rdx liest und das Ergebnis in rax ablegt, und anschließend ret.

; sum3(rdi, rsi, rdx): gibt rdi + rsi + rdx zurück
sum3:
    mov rax, rdi
    add rax, rsi
    add rax, rdx
    ret

Wenn solve dieselben Argumente erhält, die es weitergeben soll, befinden sie sich bereits in den richtigen Registern. Daher kann es sofort den Aufruf ausführen und das Ergebnis verwenden:

solve:
    call sum3       ; rax = die Summe der drei Eingaben
    imul rax, rax, 2
    ret

Ein Label, das mit einem Punkt beginnt, wie .done, gehört zum letzten Label davor ohne Punkt. Daher können zwei Funktionen jeweils ihr eigenes .done haben; benenne jede Funktion mit einem einfachen Label wie sum3.

rax ist das Ergebnisregister, daher ändert ein Aufruf es immer, selbst wenn eine Funktion aufgerufen wird, die nichts Nützliches zurückgibt. Verlass dich niemals darauf, dass rax über einen call hinweg einen Wert behält: Sichere ihn zuerst mit push.

challenge icon

Aufgabe

Einfach

Schreibe eine Funktion clamp: Ein Wert steht in rdi, eine untere Grenze in rsi und eine obere Grenze in rdx (alle Werte liegen zwischen -1000 und 1000, die untere Grenze ist niemals größer als die obere). Die Funktion gibt den Wert in rax zurück. Liegt er außerhalb der Grenzen, wird er auf die untere Grenze angehoben oder auf die obere Grenze abgesenkt. solve erhält dieselben drei Zahlen in rdi, rsi und rdx: Rufe clamp auf und gib das Ergebnis multipliziert mit 2 in rax zurück.

Beispiel: Bei der Eingabe 5 1 10 gibt das Programm 10 aus.

Schreibe deinen Code in solution.asm. Die gesperrte Datei main.asm liest die Eingabe ein, ruft solve auf und gibt die Zahl in rax oder den Namen eines callee-saved-Registers aus, das solve geändert hat.

Probier es selbst

bits 64
section .data
    changed_rbx db 'solve changed rbx', 10
    changed_rbp db 'solve changed rbp', 10
    changed_r12 db 'solve changed r12', 10
    changed_r13 db 'solve changed r13', 10
    changed_r14 db 'solve changed r14', 10
    changed_r15 db 'solve changed r15', 10
section .bss
    input_buffer resb 256
    output_buffer resb 32
    values resq 4
section .text
    global _start
    extern solve
_start:
    xor eax, eax
    xor edi, edi
    mov rsi, input_buffer
    mov edx, 255
    syscall
    test rax, rax
    jle .loaded
    mov rsi, input_buffer
    lea rdi, [input_buffer + rax]
    xor ecx, ecx
.scan:
    cmp rsi, rdi
    jae .loaded
    cmp ecx, 4
    jae .loaded
    movzx eax, byte [rsi]
    cmp al, 32
    jbe .space
    mov r10, 1
    cmp al, '-'
    jne .number
    mov r10, -1
    inc rsi
.number:
    xor eax, eax
.digit:
    cmp rsi, rdi
    jae .store
    movzx edx, byte [rsi]
    cmp dl, '0'
    jb .store
    cmp dl, '9'
    ja .store
    imul rax, rax, 10
    sub edx, '0'
    add rax, rdx
    inc rsi
    jmp .digit
.store:
    imul rax, r10
    mov [values + rcx * 8], rax
    inc ecx
.space:
    inc rsi
    jmp .scan
.loaded:
    mov rbx, 0x1111111111111111
    mov rbp, 0x2222222222222222
    mov r12, 0x3333333333333333
    mov r13, 0x4444444444444444
    mov r14, 0x5555555555555555
    mov r15, 0x6666666666666666
    mov rdi, [values]
    mov rsi, [values + 8]
    mov rdx, [values + 16]
    mov rcx, [values + 24]
    xor eax, eax
    call solve
    mov rdx, 0x1111111111111111
    lea rsi, [changed_rbx]
    cmp rbx, rdx
    jne .changed
    mov rdx, 0x2222222222222222
    lea rsi, [changed_rbp]
    cmp rbp, rdx
    jne .changed
    mov rdx, 0x3333333333333333
    lea rsi, [changed_r12]
    cmp r12, rdx
    jne .changed
    mov rdx, 0x4444444444444444
    lea rsi, [changed_r13]
    cmp r13, rdx
    jne .changed
    mov rdx, 0x5555555555555555
    lea rsi, [changed_r14]
    cmp r14, rdx
    jne .changed
    mov rdx, 0x6666666666666666
    lea rsi, [changed_r15]
    cmp r15, rdx
    jne .changed
    lea rsi, [output_buffer + 31]
    mov byte [rsi], 10
    mov ecx, 1
    xor r8d, r8d
    test rax, rax
    jns .positive
    mov r8d, 1
    neg rax
.positive:
    mov r9d, 10
.convert:
    xor edx, edx
    div r9
    add dl, '0'
    dec rsi
    mov [rsi], dl
    inc ecx
    test rax, rax
    jnz .convert
    test r8d, r8d
    jz .write
    dec rsi
    mov byte [rsi], '-'
    inc ecx
.write:
    mov edx, ecx
    mov eax, 1
    mov edi, 1
    syscall
.exit:
    mov eax, 60
    xor edi, edi
    syscall
.changed:
    mov eax, 1
    mov edi, 1
    mov edx, 18
    syscall
    jmp .exit

Alle Lektionen in Funktionen, Stack und Zeichenketten

Übe selbstständig: Assembly-Playground