Die Ziellinie

Lektion 12 von 20 im Kurs Godot-Spiel: Neon-Rennstrecke von Coddy.

Drei Runden, dann ist das Rennen vorbei. Ein state gibt an, in welchem Zustand sich das Rennen befindet:

const LAPS := 3
var state := "racing"

Wenn die Rundenanzahl LAPS erreicht, endet das Rennen: Der Zustand ist abgeschlossen, das Auto reagiert nicht mehr auf die Tasten und die Zeit wird angezeigt. Im abgeschlossenen Zustand passiert im Rennen nichts mehr:

func finish_race() -> void:
	state = "done"
	car.active = false
	$HUD/Message.text = "Finished!\nTime %s" % clock(race_time)

In car.gd legt active fest, ob die Tasten abgefragt werden. Setze Gas und Lenkung zunächst auf 0 und frage die Tasten nur ab, solange das Auto aktiv ist:

var throttle := 0.0
var steer := 0.0
if active:
	throttle = Input.get_axis("move_down", "move_up")
	steer = Input.get_axis("move_left", "move_right")

Aufgabe

Mittel

Füge in race.gd LAPS, state und var race_time := 0.0 hinzu; zähle die Zeit wie die Rundenzeit in jedem Frame hoch.
Beginne _physics_process mit: Wenn das Rennen beendet ist, return.
Rufe in finish_lap finish_race() auf, sobald laps >= LAPS gilt.
Zeige "Lap %d/%d" % [mini(laps + 1, LAPS), LAPS] im HUD an.
Füge in car.gd var active := true hinzu und lies die Tasten nur aus, solange das Fahrzeug aktiv ist (auch die Boost-Taste).

Probier es selbst

extends Node2D

@export var accel := 260.0
@export var max_speed := 200.0
@export var turn_speed := 3.2
@export var drag := 0.6
@export var grip := 7.0

var velocity := Vector2.ZERO
var boost_time := 0.0
var boost_charge := 0.0

@onready var track: Node2D = $"../Track"


func _physics_process(delta: float) -> void:
	var throttle := Input.get_axis("move_down", "move_up")
	var steer := Input.get_axis("move_left", "move_right")
	if Input.is_action_just_pressed("action") and boost_charge >= 1.0:
		boost_charge = 0.0
		boost_time = 1.0
	boost_charge = minf(1.0, boost_charge + delta / 10.0)
	$"../HUD/Boost".scale.x = boost_charge

	var forward := Vector2.RIGHT.rotated(rotation)
	var speed := velocity.dot(forward)
	var top := max_speed
	var grip_now := grip
	if boost_time > 0.0:
		boost_time -= delta
		top = max_speed * 1.3
		velocity += forward * accel * delta
	for pad in get_tree().get_nodes_in_group("boost_pads"):
		if position.distance_to(pad.position) < 22.0:
			boost_time = maxf(boost_time, 0.4)
	for oil in get_tree().get_nodes_in_group("oil"):
		if position.distance_to(oil.position) < 20.0:
			grip_now = grip * 0.12
	if not track.is_on_road(position):
		top = max_speed * 0.45
		velocity *= 1.0 - 2.5 * delta

	if throttle < 0.0 and speed > 10.0:
		velocity += forward * throttle * accel * 1.6 * delta
	else:
		velocity += forward * throttle * accel * delta
	rotation += steer * turn_speed * delta * clampf(absf(speed) / 90.0, 0.0, 1.0) * signf(speed + 0.01)

	var side := forward.orthogonal()
	velocity -= side * velocity.dot(side) * minf(1.0, grip_now * delta)
	velocity *= 1.0 - drag * delta
	if velocity.length() > top:
		velocity = velocity.move_toward(velocity.limit_length(top), accel * 2.0 * delta)
	position += velocity * delta
	$Exhaust.emitting = throttle > 0.0 or boost_time > 0.0
	$Flame.visible = boost_time > 0.0