Durchschnittsnote

Teil des Abschnitts Logik & Ablaufsteuerung der GDScript-Journey von Coddy. Lektion 46 von 78.

Aufgabe

Einfach

Berechne die Durchschnittsnote eines Schülers. Behalte alles bei, was du in den vorherigen Schritten geschrieben hast.

1. Die Funktion. Schreibe unter die anderen Funktionen calculate_average_grade(student_name: String) -> float:

Wenn student_records den Namen nicht enthält, gib Student '<name>' not found. aus und gib -1.0 zurück. Kein tatsächlicher Durchschnitt ist negativ, daher kann der Aufrufer erkennen, dass der Schüler nicht gefunden wurde.
Wenn der Schüler noch keine Noten hat, gib 0.0 zurück.
Gib andernfalls die Summe der Noten geteilt durch ihre Anzahl als float zurück.

2. Der Befehl. Füge diesen Zweig für average <name> oberhalb von ["show"] ein. Er gibt den Durchschnitt mit zwei Dezimalstellen aus, außer wenn der Schüler nicht gefunden wurde:

["average", var student]:
	var average := calculate_average_grade(student)
	if average >= 0:
		print("Average grade of '%s': %.2f" % [student, average])

Für die Befehle

add Alice 20 Math Physics
add Bob 22 Biology Chemistry
grade Alice 90
grade Alice 85
grade Bob 75
average Alice
average Bob
average Charlie
exit

lautet die Ausgabe:

Student 'Alice' added successfully.
Student 'Bob' added successfully.
Grade 90 added for student 'Alice'.
Grade 85 added for student 'Alice'.
Grade 75 added for student 'Bob'.
Average grade of 'Alice': 87.50
Average grade of 'Bob': 75.00
Student 'Charlie' not found.
Goodbye!

Probier es selbst

extends Node

# Jeder Schüler: name -> {"age": int, "grades": Array, "courses": eine Menge von Kursnamen}
var student_records := {}

func _ready():
	while true:
		var parts := Array(OS.read_string_from_stdin().split(" ", false))
		match parts:
			["add", var student, var age, ..]:
				add_student(student, int(age), parts.slice(3))
			["grade", var student, var grade]:
				add_grade(student, int(grade))
			["enrolled", var student, var course]:
				print(is_enrolled(student, course))
			["show"]:
				print(student_records)
			["exit"]:
				print("Goodbye!")
				break

func add_student(student_name: String, age: int, courses: Array) -> void:
	if student_records.has(student_name):
		print("Student '%s' already exists." % student_name)
		return
	var course_set := {}
	for course in courses:
		course_set[course] = true
	student_records[student_name] = {"age": age, "grades": [], "courses": course_set}
	print("Student '%s' added successfully." % student_name)

func add_grade(student_name: String, grade: int) -> void:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return
	student_records[student_name]["grades"].append(grade)
	print("Grade %d added for student '%s'." % [grade, student_name])

func is_enrolled(student_name: String, course: String) -> bool:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return false
	return student_records[student_name]["courses"].has(course)