Nach Kurs auflisten

Teil des Abschnitts Logik & Ablaufsteuerung der GDScript-Journey von Coddy. Lektion 47 von 78.

Aufgabe

Einfach

Liste die Studierenden auf, die einen Kurs belegen. Behalte alles bei, was du in den vorherigen Schritten geschrieben hast.

1. Die Funktion. Schreibe unter die anderen Funktionen list_students_by_course(course: String) -> Array. Sie durchläuft student_records und gibt ein Array mit den Namen der Studierenden zurück, deren "courses"-Menge den Kurs enthält, und zwar in der Reihenfolge, in der die Studierenden hinzugefügt wurden. Wenn niemand den Kurs belegt, gibt sie ein leeres Array zurück.

2. Der Befehl. Füge oberhalb von ["show"] einen Zweig für course <course> hinzu, zum Beispiel course Math. Er gibt das Array aus, das list_students_by_course() zurückgibt. Für die Befehle

add Alice 20 Math Physics
add Bob 22 Math Biology
add Diana 23 Chemistry Physics
course Math
course Physics
course Biology
course History
exit

lautet die Ausgabe:

Student 'Alice' added successfully.
Student 'Bob' added successfully.
Student 'Diana' added successfully.
["Alice", "Bob"]
["Alice", "Diana"]
["Bob"]
[]
Goodbye!

Probier es selbst

extends Node

# Jeder Schüler: Name -> {"age": int, "grades": Array, "courses": eine Menge von Kursnamen}
var student_records := {}

func _ready():
	while true:
		var parts := Array(OS.read_string_from_stdin().split(" ", false))
		match parts:
			["add", var student, var age, ..]:
				add_student(student, int(age), parts.slice(3))
			["grade", var student, var grade]:
				add_grade(student, int(grade))
			["enrolled", var student, var course]:
				print(is_enrolled(student, course))
			["average", var student]:
				var average := calculate_average_grade(student)
				if average >= 0:
					print("Average grade of '%s': %.2f" % [student, average])
			["show"]:
				print(student_records)
			["exit"]:
				print("Goodbye!")
				break

func add_student(student_name: String, age: int, courses: Array) -> void:
	if student_records.has(student_name):
		print("Student '%s' already exists." % student_name)
		return
	var course_set := {}
	for course in courses:
		course_set[course] = true
	student_records[student_name] = {"age": age, "grades": [], "courses": course_set}
	print("Student '%s' added successfully." % student_name)

func add_grade(student_name: String, grade: int) -> void:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return
	student_records[student_name]["grades"].append(grade)
	print("Grade %d added for student '%s'." % [grade, student_name])

func is_enrolled(student_name: String, course: String) -> bool:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return false
	return student_records[student_name]["courses"].has(course)

func calculate_average_grade(student_name: String) -> float:
	if not student_records.has(student_name):
		print("Student '%s' not found." % student_name)
		return -1.0
	var grades: Array = student_records[student_name]["grades"]
	if grades.is_empty():
		return 0.0
	var total := 0
	for grade in grades:
		total += grade
	return float(total) / grades.size()