=ZÄHLENWENN(A2:A8;"*") zählt die Zellen in A2:A8, die Text enthalten. Das Sternchen ist ein Platzhalter für "beliebige Zeichen", und es passt nur auf Text, also werden Zahlen, Datumswerte, WAHR/FALSCH und leere Zellen nicht gezählt. ZÄHLENWENN heißt in englischem Excel COUNTIF, und die Tabelle zeigt die Formel als =COUNTIF(A2:A8,"*"). Du kannst die Formeln in der Tabelle auch deutsch eingeben, mit Semikolons.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Entry | What | Count | |
| 2 | Apple | Text | 3 | |
| 3 | 12 | Not empty | 6 | |
| 4 | Numbers and dates | 2 | ||
| 5 | Pear | Empty | 1 | |
| 6 | 2026-01-05 | |||
| 7 | TRUE | |||
| 8 | n/a |
=ZÄHLENWENN(A2:A8;"*")D2 zählt Apple, Pear und n/a: 3. ANZAHL2 (englisch COUNTA) zählt jede gefüllte Zelle, 6, und ANZAHL (englisch COUNT) die beiden Zahlen (ein Datum ist eine Zahl). Tippe 25 in A4, und D3 und D4 steigen, während D2 bei 3 bleibt; tippe stattdessen Plum, und D2 und D3 steigen, während D4 bei 2 bleibt. ANZAHL und ANZAHL2 werden auf ihrer eigenen Seite verglichen.
Eine Zahl, die mit einem Apostroph davor eingegeben wurde, etwa '007, ist Text, also zählt "*" sie mit. Um nur Zellen mit mindestens einem Zeichen zu zählen, nimmst du "?*": Das ? muss auf ein Zeichen passen, also wird eine Formel, die eine leere Zeichenfolge ("") liefert, nie gezählt.
Zellen zählen, die einen bestimmten Text enthalten
Um Zellen zu zählen, die ein Wort irgendwo enthalten, setzt du auf beide Seiten ein Sternchen. Ohne die Sternchen muss die ganze Zelle passen.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Product | Condition | Count | |
| 2 | Apple | contains apple | 5 | |
| 3 | Pineapple | exactly apple | 1 | |
| 4 | Pear | starts with apple | 3 | |
| 5 | apple juice | word in C6 | 1 | |
| 6 | Plum | juice | ||
| 7 | Green apple | apple, case-sensitive | 3 | |
| 8 | Apple cider |
=ZÄHLENWENN(A2:A8;"*apple*")"*apple*" passt auf fünf Produkte. "apple" allein passt nur auf die Zelle, in der genau Apple steht (ZÄHLENWENN ignoriert die Schreibweise), und "apple*" auf die drei, die damit beginnen. D5 nimmt das Wort aus C6, also kannst du dort ein beliebiges Wort eintippen. D7 beachtet Groß- und Kleinschreibung: FINDEN (englisch FIND) unterscheidet anders als ZÄHLENWENN apple von Apple, also zählen nur Pineapple, apple juice und Green apple. Das -- macht aus den Ergebnissen WAHR/FALSCH 1 und 0, die SUMMENPRODUKT (englisch SUMPRODUCT) addiert.
Wenn eine Zelle Text enthält, dann einen Wert zurückgeben
Um jede Zeile zu markieren, prüfst du eine Zelle nach der anderen. SUCHEN("apple";A2) liefert die Position, an der apple beginnt, oder #WERT! (englisch #VALUE!), wenn es nicht vorkommt. ISTZAHL (englisch ISNUMBER) macht daraus WAHR oder FALSCH, und WENN wählt das Ergebnis.
| A | B | C | |
|---|---|---|---|
| 1 | Product | Contains apple? | Any text? |
| 2 | Apple | Yes | Text |
| 3 | Pear | No | Text |
| 4 | Pineapple | Yes | Text |
| 5 | 42 | No | Not text |
| 6 | Green apple | Yes | Text |
| 7 | 2026-02-01 | No | Not text |
=WENN(ISTZAHL(SUCHEN("apple";A2));"Yes";"No")Beide Spalten sind nach unten ausgefüllt. B zeigt Yes für Apple, Pineapple und Green apple. C verwendet ISTTEXT (englisch ISTEXT), das eine andere Frage beantwortet: Steht überhaupt Text in der Zelle? 42 und das Datum sind Zahlen, also sind sie "Not text". Nimm FINDEN statt SUCHEN, wenn die Schreibweise zählt. Mehr zu den beiden Funktionen, und warum SUCHEN die Schreibweise ignoriert, steht unter FINDEN und SUCHEN.
=WENN(ZÄHLENWENN(A2;"*apple*");"Yes";"No") macht dieselbe Prüfung mit ZÄHLENWENN: Eine Anzahl von 1 zählt als WAHR und 0 als FALSCH.
Zellen zählen, die eines von mehreren Wörtern enthalten
Addierst du zwei ZÄHLENWENN, wird eine Zelle doppelt gezählt, wenn sie beide Wörter enthält. Prüf stattdessen jede Zelle einmal: SUCHEN für jedes Wort, die WAHR-Ergebnisse addieren und die Zeilen zählen, in denen die Summe über 0 liegt.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Product | Formula | Count | |
| 2 | Apple | Two COUNTIFs | 5 | |
| 3 | Orange juice | Each cell once | 4 | |
| 4 | Pear | |||
| 5 | apple juice | |||
| 6 | Plum | |||
| 7 | Green apple |
=ZÄHLENWENN(A2:A7;"*apple*")+ZÄHLENWENN(A2:A7;"*juice*")Vier Produkte enthalten apple oder juice, aber die beiden ZÄHLENWENN liefern 5, weil apple juice von beiden gezählt wird. Die Variante mit SUMMENPRODUKT liefert 4.
Übung: die Textzellen zählen
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Delivery | Weight | What | Count | |
| 2 | D-1 | 12 | Notes | ||
| 3 | D-2 | 9 | |||
| 4 | D-3 | damaged | |||
| 5 | D-4 | 15 | |||
| 6 | D-5 | missing | |||
| 7 | D-6 | ||||
| 8 | D-7 | late |
Du bist dran: Manche Lieferungen haben ein Gewicht, andere eine Notiz. Zähle die Zellen in B2:B8, die Text enthalten. Schreib die Formel in E2.
Warum die Zahl der Textzellen nicht stimmt
- Als Text gespeicherte Zahlen werden mitgezählt. Eine Spalte, die aus einem anderen System importiert wurde, kann
'125als Text enthalten."*"zählt sie, ANZAHL nicht. Ist ANZAHL auf einer Spalte mit Zahlen kleiner als ANZAHL2, sind einige davon Text; siehe als Text gespeicherte Zahlen. - Zellen, die nur leer aussehen. Eine Zelle mit einem Leerzeichen ist Text und wird gezählt. Mit
=SUMMENPRODUKT(--(LÄNGE(GLÄTTEN(A2:A8))>0))zählst du Zellen mit sichtbaren Zeichen. - WAHR und FALSCH sind kein Text.
"*"überspringt sie, genauso wie Fehlerwerte wie #NV (englisch#N/A; die Tabellen hier zeigen die englischen Fehlernamen). - ZÄHLENWENN ignoriert die Schreibweise. Für eine Zählung mit Groß- und Kleinschreibung nimmst du FINDEN in SUMMENPRODUKT, wie in der zweiten Tabelle.
Häufig gestellte Fragen
Wie zähle ich in Excel Zellen, die beliebigen Text enthalten?
Nimm =ZÄHLENWENN(A2:A8;"*"). Das Sternchen passt auf jeden Text, also zählt die Formel jede Textzelle und überspringt Zahlen, Datumswerte, WAHR/FALSCH und leere Zellen.
Wie zähle ich Zellen, die einen bestimmten Text enthalten?
Setz Sternchen um das Wort: =ZÄHLENWENN(A2:A8;"*apple*") zählt Zellen, in denen apple irgendwo vorkommt, in beliebiger Schreibweise. Ohne die Sternchen zählt "apple" nur Zellen, in denen genau apple steht.
Wie schreibe ich "wenn Zelle Text enthält, dann" in Excel?
Kombiniere WENN, ISTZAHL und SUCHEN: =WENN(ISTZAHL(SUCHEN("apple";A2));"Yes";"No"). SUCHEN liefert eine Position, wenn es den Text findet, und einen Fehler, wenn nicht, und ISTZAHL macht daraus WAHR oder FALSCH.
Wie prüfe ich, ob eine Zelle überhaupt Text enthält?
Nimm =ISTTEXT(A2), das WAHR für Text und FALSCH für Zahlen, Datumswerte und leere Zellen liefert. In WENN: =WENN(ISTTEXT(A2);"Text";"Not text").
