=DATEDIF(A2;B2;"M") zählt die vollständigen Monate zwischen dem Startdatum in A2 und dem Enddatum in B2. Das dritte Argument, die Einheit, legt fest, was gezählt wird: "Y" Jahre, "M" Monate, "D" Tage, dazu drei Einheiten, die einen Teil der Datumswerte ignorieren. DATEDIF heißt in deutschem Excel genauso, nur die Argumente trennst du mit Semikolons; die Tabelle zeigt die englische Schreibweise mit Kommas, nimmt die Formeln aber auch mit Semikolons an.
| A | B | C | D | E | |
|---|---|---|---|---|---|
| 1 | Start | End | Unit | Result | |
| 2 | 2024-04-15 | 2026-09-10 | Y | 2 | |
| 3 | M | 28 | |||
| 4 | D | 878 | |||
| 5 | YM | 4 | |||
| 6 | MD | 26 | |||
| 7 | YD | 148 |
=DATEDIF($A$2;$B$2;D3)Vom 2024-04-15 bis zum 2026-09-10 sind es 2 vollständige Jahre, 28 vollständige Monate und 878 Tage. Ändere das Enddatum in B2 und sieh zu, wie sich jede Einheit bewegt. Die Einheit kann in der Formel stehen ("M") oder, wie hier, aus einer Zelle gelesen werden.
Syntax und Einheiten von DATEDIF
=DATEDIF(start_date, end_date, unit)
| Einheit | Zählt | 2024-04-15 bis 2026-09-10 |
|---|---|---|
"Y" | vollständige Jahre | 2 |
"M" | vollständige Monate | 28 |
"D" | Tage | 878 |
"YM" | Monate nach dem letzten vollständigen Jahr | 4 |
"MD" | Tage nach dem letzten vollständigen Monat | 26 |
"YD" | Tage nach dem letzten vollständigen Jahr | 148 |
"Vollständig" heißt, dass DATEDIF nie aufrundet. Vom 31. Januar bis zum 28. Februar sind es 0 Monate, weil der 28. Februar vor der Ein-Monats-Marke liegt. Die Einheit unterscheidet keine Groß- und Kleinschreibung ("m" geht auch), aber sie muss in Anführungszeichen oder in einer Zelle stehen.
Warum DATEDIF nicht in der Funktionsliste steht
DATEDIF kam von Lotus 1-2-3 zu Excel, und Microsoft behält es nur aus Kompatibilitätsgründen. Es fehlt im Dialog Funktion einfügen, die AutoVervollständigen-Liste für Formeln schlägt es nicht vor, und keine QuickInfo zeigt seine Argumente. Es rechnet trotzdem in jeder Excel-Version unter Windows und Mac und in Google Sheets. Tippe den ganzen Namen und die öffnende Klammer, =DATEDIF(, und ergänze die Argumente selbst.
Monate zwischen zwei Datumswerten
Vollständige Monate brauchen die meisten Verträge, Abos und Berichte zur Betriebszugehörigkeit. Für einen Dezimalwert liefert BRTEILJAHRE(A2;B2)*12 die Monate mit Bruchteil (die Standardbasis zählt jeden Monat mit 30 Tagen).
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Start | End | Full months | Decimal months |
| 2 | 2025-03-10 | 2026-01-05 | 9 | 9.8 |
| 3 | 2024-04-15 | 2026-09-10 | 28 | 28.8 |
| 4 | 2026-01-31 | 2026-02-28 | 0 | 0.9 |
| 5 | 2025-11-01 | 2026-05-01 | 6 | 6.0 |
=DATEDIF(A2;B2;"M")Das erste Abo lief 9 vollständige Monate: Der 5. Januar liegt vor dem 10., also wird der zehnte Monat nicht gezählt. Die dritte Zeile zeigt den Fall 31. Januar, 0 Monate.
Jahre, Monate und Tage zusammen
"Y", "YM" und "MD" sind für den gemeinsamen Einsatz gemacht. Jede Einheit macht dort weiter, wo die vorherige aufgehört hat, also beantworten die drei "wie lange genau": 2 Jahre, 4 Monate und 26 Tage für die Datumswerte oben. Alter berechnen verwendet dieselben drei Einheiten mit Geburtsdaten.
| A | B | C | D | E | F | |
|---|---|---|---|---|---|---|
| 1 | Hired | Years | Months | Days | Service | As of |
| 2 | 2019-06-03 | 7 | 3 | 27 | 7y 3m 27d | 2026-09-30 |
| 3 | 2023-11-20 | 2 | 10 | 10 | 2y 10m 10d |
=B2&"y "&C2&"m "&D2&"d"Die erste Mitarbeiterin ist am 2026-09-30 seit 7 Jahren, 3 Monaten und 27 Tagen im Unternehmen.
Warum DATEDIF #ZAHL! liefert
DATEDIF zählt nicht rückwärts. Liegt das Startdatum nach dem Enddatum, ist das Ergebnis #ZAHL! (englisch #NUM!; die Tabellen hier zeigen die englischen Fehlernamen). Kann die Reihenfolge wechseln, gib DATEDIF mit MIN das frühere und mit MAX das spätere Datum.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Start | End | DATEDIF | With MIN and MAX |
| 2 | 2026-03-10 | 2026-01-05 | #NUM! | 64 |
#NUM! Eine Zahl liegt außerhalb des Bereichs, den diese Funktion annimmt.Im deutschen Excel: =DATEDIF(A2;B2;"D")C2 zeigt #NUM!; D2 liefert 64. Nur für Tage liefert =ABS(B2-A2) dieselben 64 ohne DATEDIF. DATEDIF liefert #ZAHL! auch bei einer unbekannten Einheit wie "W", und #WERT! (englisch #VALUE!), wenn ein Datum Text ist, den Excel nicht als Datum lesen kann.
Die Einheit MD kann falsch sein
Die Dokumentation von Microsoft selbst rät von "MD" ab: Wenn es den Starttag im Monat vor dem Enddatum nicht gibt, kann die Einheit eine negative Zahl liefern.
| A | B | C | D | |
|---|---|---|---|---|
| 1 | Start | End | MD | D |
| 2 | 2026-01-31 | 2026-03-01 | -2 | 29 |
=DATEDIF(A2;B2;"MD")Vom 31. Januar bis zum 1. März ist das Ergebnis von "MD" -2: DATEDIF zählt ab dem "31. Februar", der in den 3. März übergeht, zwei Tage nach dem Enddatum. Die Zahl der Tage, 29, stimmt. Können Startdaten auf den 29. bis 31. fallen, zeig die Dauer in Tagen an, oder prüf den MD-Wert von Hand.
Übung: die Monate zählen
| A | B | C | |
|---|---|---|---|
| 1 | Start | End | Months |
| 2 | 2025-03-10 | 2026-01-05 |
Du bist dran: Zähle in C2 die vollständigen Monate zwischen dem Startdatum in A2 und dem Enddatum in B2.
| A | B | C | |
|---|---|---|---|
| 1 | Date 1 | Date 2 | Days |
| 2 | 2026-04-18 | 2026-02-01 |
Du bist dran: Zähle in C2 die Tage zwischen den beiden Datumswerten, egal welcher zuerst kommt.
Häufig gestellte Fragen
Was macht DATEDIF in Excel?
Es zählt die vollständigen Jahre, Monate oder Tage zwischen zwei Datumswerten: =DATEDIF(A2;B2;"Y") für Jahre, "M" für Monate, "D" für Tage. Das Startdatum muss zuerst stehen.
Warum finde ich DATEDIF in Excel nicht?
DATEDIF gibt es nur noch aus Kompatibilität zu Lotus 1-2-3, deshalb lässt Excel es im Dialog Funktion einfügen und in der AutoVervollständigen-Liste für Formeln weg. Es funktioniert trotzdem in jeder Version: Tippe =DATEDIF( vollständig und ergänze die Argumente selbst.
Warum liefert DATEDIF #ZAHL!?
Das Startdatum liegt nach dem Enddatum. Vertausche die Argumente, oder nimm =DATEDIF(MIN(A2;B2);MAX(A2;B2);"D"), wenn du nicht weißt, welches Datum zuerst kommt.
Was ist der Unterschied zwischen YM, MD und YD in DATEDIF?
Sie ignorieren einen Teil der Datumswerte: "YM" liefert die Monate, die nach den vollen Jahren übrig bleiben, "MD" die Tage nach den vollen Monaten und "YD" die Tage nach den vollen Jahren. Zusammen ergeben "Y", "YM" und "MD" ein Alter in Jahren, Monaten und Tagen.
Funktioniert DATEDIF in Google Sheets?
Ja, mit denselben Argumenten und Einheiten. Google Sheets führt es anders als Excel auch in seiner Funktionshilfe auf.
