ブレイクアウトのゲームオーバー

CoddyのGodotジャーニー「プロジェクト」セクションの一部。レッスン 9/36。

ミスが3回になるとゲームを終了します。残りライフが0になったら、Game Overを表示してget_tree().paused = trueで一時停止します。パドルとボールはPausableなので、動きが止まります。MainはAlwaysなので、実行を続けてEnterキーを読み取れます。

func _process(delta):
	if get_tree().paused and Input.is_action_just_pressed("action"):
		get_tree().paused = false
		get_tree().reload_current_scene()

再読み込みする前に一時停止を解除してください。一時停止はシーンではなくツリーに適用されるため、シーンを再読み込みすると一時停止した状態で始まってしまいます。

チャレンジ

難しい

最後のライフがなくなったらゲームを終了します。

_on_missedで、livesが0のとき、$HUD/MessageにGame Overを表示してゲームを一時停止します。
_processを追加します。ゲームが一時停止中にactionが押された直後であれば、一時停止を解除してからシーンを再読み込みします。

「プレイ」を押して、ボールを3回外します。「Game Over」が表示され、ボールが止まります。Enterキーで再開します。その後、「確認」を押します。

自分で試してみよう

extends Node2D

const BRICK = preload("res://brick.tscn")
const COLORS = [Color(1, 0.42, 0.42), Color(1, 0.78, 0.34), Color(0.49, 0.95, 0.75), Color(0.369, 0.635, 1), Color(0.75, 0.82, 0.95)]

var score = 0
var lives = 3

func _ready():
	for row in 5:
		for column in 8:
			var brick = BRICK.instantiate()
			brick.position = Vector2(68 + column * 72, 60 + row * 26)
			brick.color = COLORS[row]
			add_child(brick)
	$Ball.brick_broken.connect(_on_brick_broken)
	$HUD/Score.text = "Score: 0"
	$Ball.missed.connect(_on_missed)
	$HUD/Lives.text = "Lives: 3"

func _on_brick_broken():
	score += 10
	$HUD/Score.text = "Score: %d" % score

func _on_missed():
	lives -= 1
	$HUD/Lives.text = "Lives: %d" % lives