壁を一掃する

CoddyのGodotジャーニー「プロジェクト」セクションの一部。レッスン 9/33。

最後のステップは勝利条件を作ることです。すべてのブロックを壊しましょう。

残っているブロックの数を数えます。40から始めて、brick_brokenが届くたびに1つ減らします。0になると壁がなくなります。

bricks_left -= 1
if bricks_left == 0:
	$HUD/Message.text = "You Win!"
	get_tree().paused = true

0かどうかを確認する前に1つ減らします。先に確認すると、最後のブロックのときに確認結果は1となり、0になることはありません。

ゲームオーバー画面でEnterキーを押すと、ここでも新しいゲームが始まります。これでBreakoutは完成です。

チャレンジ

中級

main.gd内で:

var bricks_left = 40を追加します。
ブロックが壊れるたびに、残りの数を1減らします。
残りがなくなったら、$HUD/MessageにYou Win!を表示して、ゲームを一時停止します。

自分で試してみよう

extends Node2D

const BRICK = preload("res://brick.tscn")
const COLORS = [Color(1, 0.42, 0.42), Color(1, 0.78, 0.34), Color(0.49, 0.95, 0.75), Color(0.369, 0.635, 1), Color(0.75, 0.82, 0.95)]

var score = 0
var lives = 3

func _ready():
	for row in 5:
		for column in 8:
			var brick = BRICK.instantiate()
			brick.position = Vector2(68 + column * 72, 60 + row * 26)
			brick.color = COLORS[row]
			add_child(brick)
	$Ball.brick_broken.connect(_on_brick_broken)
	$HUD/Score.text = "Score: 0"
	$Ball.missed.connect(_on_missed)
	$HUD/Lives.text = "Lives: 3"

func _process(delta):
	if get_tree().paused and Input.is_action_just_pressed("action"):
		get_tree().paused = false
		get_tree().reload_current_scene()

func _on_brick_broken():
	score += 10
	$HUD/Score.text = "Score: %d" % score

func _on_missed():
	lives -= 1
	$HUD/Lives.text = "Lives: %d" % lives
	if lives == 0:
		$HUD/Message.text = "Game Over"
		get_tree().paused = true